-
Notifications
You must be signed in to change notification settings - Fork 0
/
Cortical_Soma_I_K.mod
83 lines (63 loc) · 1.68 KB
/
Cortical_Soma_I_K.mod
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
TITLE Delayed-rectifier Potassium Current for Cortical Neuron Soma
COMMENT
Model Reference:
Pospischil, M., Toledo-Rodriguez, M., Monier, C., Piwkowska, Z.,
Bal, T., Frégnac, Y., Markram, H. and Destexhe, A., 2008.
"Minimal Hodgkin–Huxley type models for different classes of
cortical and thalamic neurons."
Biological cybernetics, 99(4-5), pp.427-441.
Implemented by John Fleming - [email protected] - 06/12/18
Edits:
ENDCOMMENT
UNITS {
(mV) = (millivolt)
(mA) = (milliamp)
(S) = (siemens)
}
NEURON {
SUFFIX cortical_soma_i_k
USEION k WRITE ik : Using k ion, treat the reversal potential as a parameter and write to ik so the total k current can be tracked
RANGE g_K, i_K : Potassium current, specific conductance and equilibrium potential
}
PARAMETER {
ek = -100 (mV)
i_K = 0.0 (mA/cm2) : Parameter to record this current separately to total sodium current
g_K = 5e-3 (S/cm2)
V_T = -55(mV)
}
ASSIGNED {
v (mV)
ik (mA/cm2)
alpha_n
beta_n
}
STATE {
n
}
BREAKPOINT {
SOLVE states METHOD cnexp
ik = g_K*n*n*n*n*(v - ek)
i_K = ik : Record i_K (just this potassium current) to check it is working
}
UNITSOFF
INITIAL {
settables(v) : ** Need to double check these intials are correct
n = 0
}
DERIVATIVE states {
settables(v)
n' = alpha_n*(1-n)-beta_n*n
}
PROCEDURE settables(v) {
TABLE alpha_n, beta_n DEPEND V_T FROM -100 TO 100 WITH 400
alpha_n = 0.032 * vtrap(-(v-V_T-15), 5)
beta_n = 0.5*exp(-(v-V_T-10)/40)
}
FUNCTION vtrap(x,y) {
if (fabs(x/y) < 1e-6) {
vtrap = y*(1 - x/y/2)
}else{
vtrap = x/(exp(x/y)-1)
}
}
UNITSON