-
Notifications
You must be signed in to change notification settings - Fork 13
/
FEInfoExtractor.wl
1361 lines (1158 loc) · 29.1 KB
/
FEInfoExtractor.wl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ::Package:: *)
(* ::Subsubsection::Closed:: *)
(*Indentation Fixer*)
(* ::Input:: *)
(*<<BTools`FrontEnd`*)
(* ::Input:: *)
(*MakeIndentable["IndentCharacter"->" "]*)
(* ::Input:: *)
(*CurrentValue[EvaluationNotebook[],{TaggingRules, "IndentCharacter"}]=" ";*)
(*BatchIndentationEvent["Restore", *)
(* CellStyle->"Code"*)
(* ]*)
(* ::Input:: *)
(*CurrentValue[EvaluationNotebook[],{TaggingRules, "IndentCharacter"}]="\t";*)
(*BatchIndentationEvent["Replace", *)
(* CellStyle->"Code"*)
(* ]*)
(* ::Section:: *)
(*FEInfoExtractor*)
BeginPackage["FEInfoExtractor`"];
ClearAll["FEInfoExtractor`*", "FEInfoExtractor`*`*"];
(*Package Declarations*)
AutoFrontEndInfo::usage=
"AutoFrontEndInfo[function, ops] generates the front-end integration info
AutoFrontEndInfo[{fns...}] generates a combined expression for all fns
AutoFrontEndInfo[stringPat] generates for Names[stringPat]";
AutoFrontEndInfoExport::usage=
"AutoFrontEndInfoExport[file, e] exports the auto-built integration info to file";
(* ::Subsubsection::Closed:: *)
(*Private Declarations*)
BeginPackage["`Package`"];
(*Package Declarations*)
getCodeValues::usage="getCodeValues[f, vs]";
extractorLocalized::usage="extractorLocalized[s]";
$usageTypeReplacements::usage="$usageTypeReplacements";
$usageSymNames::usage="$usageSymNames";
symbolUsageReplacementPattern::usage="symbolUsageReplacementPattern[names, conts]";
usagePatternReplace::usage="usagePatternReplace[vals, reps]";
generateSymbolUsage::usage="generateSymbolUsage[f, defaultMessages]";
autoCompletionsExtractSeeder::usage="autoCompletionsExtractSeeder[_ | (Blank | BlankSequence)[Hue | RGBColor | XYZColor | LABColor], n]
autoCompletionsExtractSeeder[_, n]
autoCompletionsExtractSeeder[_ | (Blank | BlankSequence)[File] | _File, n]
autoCompletionsExtractSeeder[Alternatives[s], n]
autoCompletionsExtractSeeder[_, n]
autoCompletionsExtractSeeder[a, n]";
autoCompletionsExtract::usage="autoCompletionsExtract[_[a]]
autoCompletionsExtract[f]";
generateAutocompletions::usage="generateAutocompletions[f, otherAutos]";
$autoCompletionFormats::usage="$autoCompletionFormats";
$autocompletionAliases::usage="$autocompletionAliases";
$autocompletionTable::usage="$autocompletionTable";
autocompletionPreCompile::usage="autocompletionPreCompile[v]
autocompletionPreCompile[o]
autocompletionPreCompile[s, v]
autocompletionPreCompile[l, v]";
addAutocompletions::usage="addAutocompletions[pats]
addAutocompletions[pat]";
reducePatterns::usage="reducePatterns[p]";
extractArgStructureHead::usage="extractArgStructureHead[f, defs]";
generateArgPatList::usage="generateArgPatList[f, defs]";
reconstructPatterns::usage="reconstructPatterns[p]";
argPatPartLens::usage="argPatPartLens[patList]";
mergeArgPats::usage="mergeArgPats[pats, returnNum]";
generateSIArgPat::usage="generateSIArgPat[f]";
generateSILocVars::usage="generateSILocVars[f]";
generateSIColEq::usage="generateSIColEq[f]";
generateSIOpNames::usage="generateSIOpNames[f]";
generateSyntaxInformation::usage="generateSyntaxInformation[f, ops]";
generateArgCount::usage="generateArgCount[f]";
setArgCount::usage="setArgCount[f, minA, maxA, noo]";
generateAutoFrontEndInfo::usage="generateAutoFrontEndInfo[f, ops]";
EndPackage[];
Begin["`Private`"];
(* ::Subsection:: *)
(*Implementation*)
(*Package Implementation*)
(* ::Subsection:: *)
(*CodeValues*)
(* ::Subsubsection::Closed:: *)
(*getCodeValues*)
getCodeValues[f_Symbol,
vs :
{Repeated[
OwnValues | DownValues | SubValues | UpValues]} : {OwnValues,
DownValues, SubValues, UpValues}
] :=
Select[
If[Intersection[Attributes@f, { ReadProtected, Locked}] === {
Locked, ReadProtected},
{},
Join @@ Map[#[f] &, vs]
],
FreeQ[ArgumentCountQ]
];
getCodeValues~SetAttributes~HoldFirst
(* ::Subsection:: *)
(*Usage*)
(* ::Subsubsection::Closed:: *)
(*usagePatternReplace*)
extractorLocalized[s_] :=
Block[{$ContextPath = {"System`"}, $Context =
"FEInfoExtractor`Private`"},
Internal`WithLocalSettings[
BeginPackage["FEInfoExtractor`Private`"];
Off[General::shdw];,
ToExpression[s],
On[General::shdw];
EndPackage[]
]
];
$usageTypeReplacements =
{
Integer -> extractorLocalized["int"],
Real -> extractorLocalized["float"],
String -> extractorLocalized["str"],
List -> extractorLocalized["list"],
Association -> extractorLocalized["assoc"],
Symbol -> extractorLocalized["sym"]
};
$usageSymNames =
{
Alternatives -> extractorLocalized["alt"],
PatternTest -> extractorLocalized["test"],
Condition -> extractorLocalized["cond"],
s_Symbol :>
RuleCondition[
extractorLocalized@
ToLowerCase[StringTake[SymbolName[Unevaluated@s], UpTo[3]]],
True
]
};
symbolUsageReplacementPattern[names_, conts_] :=
s_Symbol?(
GeneralUtilities`HoldFunction[
! MatchQ[Context[#], conts] &&
!
MemberQ[$ContextPath, Context[#]] &&
!
KeyMemberQ[names, SymbolName@Unevaluated[#]]
]
) :>
RuleCondition[
ToExpression@
Evaluate[$Context <>
With[{name = SymbolName@Unevaluated[s]},
If[StringLength@StringTrim[name, "$"] > 0,
StringTrim[name, "$"],
name
]
]
],
True];
usagePatternReplace[
vals_,
reps_: {}
] :=
With[{
names = AssociationMap[Null &, {}(*Names[]*)],
conts =
Alternatives @@ {
"System`", "FrontEnd`",
"PacletManager`", "Internal`"
},
repTypes=Alternatives@@Map[Blank, Keys@$usageTypeReplacements]
},
Replace[
Replace[
#,
{
Verbatim[HoldPattern][a___] :> a
},
{2, 10}
],
Join[$usageTypeReplacements, $usageSymNames],
Depth[#]
] &@
ReplaceRepeated[
FixedPoint[
Replace[
#,
{
Verbatim[Pattern][_, e_] :>
e,
Verbatim[HoldPattern][Verbatim[Pattern][_, e_]] :>
HoldPattern[e],
Verbatim[HoldPattern][Verbatim[HoldPattern][e_]] :>
HoldPattern[e]
},
1
] &,
vals
],
Flatten@{
reps,
Verbatim[PatternTest][_, ColorQ] :>
extractorLocalized@"color",
Verbatim[PatternTest][_, ImageQ] :>
extractorLocalized@"img",
Verbatim[Optional][name_, _] :>
name,
Verbatim[Pattern][_, _OptionsPattern] :>
Sequence[],
Verbatim[Pattern][name_, _] :>
name,
Verbatim[PatternTest][p_, _] :>
p,
Verbatim[Condition][p_, _] :>
p,
(* for dispatching functions by Alternatives *)
Verbatim[Alternatives][a_, ___][___] |
Verbatim[Alternatives][a_, ___][___][___] |
Verbatim[Alternatives][a_, ___][___][___][___] |
Verbatim[Alternatives][a_, ___][___][___][___][___] |
Verbatim[Alternatives][a_, ___][___][___][___][___][___] :>
a,
Verbatim[Alternatives][a_, ___] :>
RuleCondition[
Blank[
Replace[
Hold@a,
{
Hold[p : Verbatim[HoldPattern][_]] :>
p,
Hold[repTypes]:>Head[a],
Hold[e_[___]] :> e,
_ :> a
}
]
],
True
],
Verbatim[Verbatim][p_][a___] :>
p,
Verbatim[Blank][] :>
extractorLocalized@"expr",
Verbatim[Blank][
t : Alternatives @@ Keys[$usageTypeReplacements]] :>
RuleCondition[
Replace[t,
$usageTypeReplacements
],
True
],
Verbatim[Blank][t_] :>
t,
Verbatim[BlankSequence][] :>
Sequence @@ extractorLocalized[{"expr1", "expr2"}],
Verbatim[BlankNullSequence][] :>
Sequence[],
symbolUsageReplacementPattern[names, conts],
h_[a___, Verbatim[Sequence][b___], c___] :> h[a, b, c]
}
]
];
(* ::Subsubsection::Closed:: *)
(*generateSymbolUsage*)
$pkgCont = $Context;
$defaultUsageTemplate = "`` has no usage message";
generateSymbolUsage[
f_Symbol,
defaultMessages : {(_Rule | _RuleDelayed) ...} : {},
uTemp:_String|Automatic:Automatic
] :=
With[
{
ut=
Replace[uTemp, Automatic->$defaultUsageTemplate],
uml =
Replace[defaultMessages,
{
(h : Rule | RuleDelayed)[Verbatim[HoldPattern][pat___], m_] :>
h[HoldPattern[Verbatim[HoldPattern][pat]], m],
(h : Rule | RuleDelayed)[pat___, m_] :>
h[Verbatim[HoldPattern][pat], m],
_ -> Nothing
},
{1}
]
},
DeleteDuplicates@Flatten@
Replace[
DeleteDuplicates@usagePatternReplace[Keys@getCodeValues[f]],
{
Verbatim[HoldPattern][s_[a___]]:>
With[
{
(* original usage message *)
uu =
StringTrim@
Replace[HoldPattern[s[a]] /. uml,
Except[_String] :>
Replace[Quiet@s::usage, Except[_String] -> ""]
],
sn = ToString[Unevaluated@s],
(* head for the usage message I'm going to add*)
meuu =
StringReplace[ToString[Unevaluated[s[a]], InputForm],
$pkgCont -> ""]
},
Which[!StringContainsQ[uu, StringSplit[meuu, "["][[1]]<>"[" ],
Which[
uu == "",
TemplateApply[ut, meuu],
! StringStartsQ[uu, sn],
meuu<>" "<>uu,
True,
{uu, TemplateApply[ut, meuu]}
],
!StringContainsQ[uu, meuu],
TemplateApply[ut, meuu],
True,
StringCases[
uu,
(StartOfLine | StartOfString) ~~
Except["\n"]... ~~ meuu ~~
Except["\n"]... ~~ EndOfLine,
1
][[1]]
]
],
_ -> Nothing
},
{1}
]
];
generateSymbolUsage~SetAttributes~HoldFirst;
(* ::Subsection:: *)
(*AutoComplete*)
(* ::Subsubsection::Closed:: *)
(*autoCompletionsExtractSeeder*)
Attributes[autoCompletionsExtractSeeder] =
{
HoldFirst
};
autoCompletionsExtractSeeder[
HoldPattern[Verbatim[PatternTest][_, ColorQ]] |
(Blank | BlankSequence)[Hue | RGBColor | XYZColor | LABColor],
n_
] := Sow[n -> "Color"];
autoCompletionsExtractSeeder[
HoldPattern[Verbatim[PatternTest][_, DirectoryQ]],
n_
] := Sow[n -> "Directory"];
autoCompletionsExtractSeeder[
HoldPattern[Verbatim[PatternTest][_, FileExistsQ]] |
(Blank | BlankSequence)[File] | _File,
n_
] := Sow[n -> "FileName"];
autoCompletionsExtractSeeder[
Verbatim[Alternatives][s__String],
n_
] :=
Sow[n -> {s}];
autoCompletionsExtractSeeder[
Verbatim[Pattern][_, b_],
n_
] := autoCompletionsExtractSeeder[b, n];
autoCompletionsExtractSeeder[
Verbatim[Optional][a_, ___],
n_
] := autoCompletionsExtractSeeder[a, n];
(* ::Subsubsection::Closed:: *)
(*autoCompletionsExtract*)
Attributes[autoCompletionsExtract] =
{
HoldFirst
};
autoCompletionsExtract[Verbatim[HoldPattern][_[a___]]] :=
{ReleaseHold@
MapIndexed[
Function[Null, autoCompletionsExtractSeeder[#, #2[[1]]],
HoldAllComplete],
Hold[a]
]
};
autoCompletionsExtract[f_Symbol] :=
Flatten@
Reap[
autoCompletionsExtract /@
Replace[
Keys@getCodeValues[f, {DownValues, SubValues, UpValues}],
{
Verbatim[HoldPattern][
HoldPattern[
f[a___][___]|
f[a___][___][___]|
f[a___][___][___][___]|
f[a___][___][___][___][___]|
f[a___][___][___][___][___][___]
]
]:>HoldPattern[f[a]],
Verbatim[HoldPattern][
HoldPattern[
_[___, f[a___], ___]|
_[___, f[a___][___], ___]|
_[___, f[a___][___][___], ___]|
_[___, f[a___][___][___][___], ___]|
_[___, f[a___][___][___][___][___], ___]|
_[___, f[a___][___][___][___][___][___], ___]
]
]:>HoldPattern[f[a]]
},
{1}
]
][[2]]
(* ::Subsubsection::Closed:: *)
(*generateAutocompletions*)
generateAutocompletions[
f : _Symbol : None,
otherAutos : {(_Integer -> _) ...} : {}
] :=
With[
{
gg =
Join[
GroupBy[
If[Unevaluated[f] =!= None,
autoCompletionsExtract[f],
{}
],
First -> Last,
Replace[{s_, ___} :> s]
],
GroupBy[
otherAutos,
First -> Last
]
]
},
With[{km = Max@Append[Keys@gg, 0]},
Table[
Lookup[gg, i, None],
{i, km}
]
]
];
SetAttributes[generateAutocompletions, HoldFirst];
(* ::Subsection:: *)
(*Set Autocompletions*)
(* ::Subsubsection::Closed:: *)
(*$autoCompletionFormats*)
$autoCompletionFormats =
Alternatives @@ Join @@ {
Range[0, 9],
{
_String?(FileExtension[#] === "trie" &),
{
_String | (Alternatives @@ Range[0, 9]) | {__String},
(("URI" | "DependsOnArgument") -> _) ...
},
{
_String | (Alternatives @@ Range[0, 9]) | {__String},
(("URI" | "DependsOnArgument") -> _) ...,
(_String | (Alternatives @@ Range[0, 9]) | {__String})
},
{
__String
}
},
{
"codingNoteFontCom",
"ConvertersPath",
"ExternalDataCharacterEncoding",
"MenuListCellTags",
"MenuListConvertFormatTypes",
"MenuListDisplayAsFormatTypes",
"MenuListFonts",
"MenuListGlobalEvaluators",
"MenuListHelpWindows",
"MenuListNotebookEvaluators",
"MenuListNotebooksMenu",
"MenuListPackageWindows",
"MenuListPalettesMenu",
"MenuListPaletteWindows",
"MenuListPlayerWindows",
"MenuListPrintingStyleEnvironments",
"MenuListQuitEvaluators",
"MenuListScreenStyleEnvironments",
"MenuListStartEvaluators",
"MenuListStyleDefinitions",
"MenuListStyles",
"MenuListStylesheetWindows",
"MenuListTextWindows",
"MenuListWindows",
"PrintingStyleEnvironment",
"ScreenStyleEnvironment",
"Style"
}
};
(* ::Subsubsection::Closed:: *)
(*$autocompletionAliases*)
$autocompletionAliases =
{
"None" | None | Normal -> 0,
"AbsoluteFileName" | AbsoluteFileName -> 2,
"FileName" | File | FileName -> 3,
"Color" | RGBColor | Hue | XYZColor -> 4,
"Package" | Package -> 7,
"Directory" | Directory -> 8,
"Interpreter" | Interpreter -> 9,
"Notebook" | Notebook -> "MenuListNotebooksMenu",
"StyleSheet" -> "MenuListStylesheetMenu",
"Palette" -> "MenuListPalettesMenu",
"Evaluator" | Evaluator -> "MenuListGlobalEvaluators",
"FontFamily" | FontFamily -> "MenuListFonts",
"CellTag" | CellTags -> "MenuListCellTags",
"FormatType" | FormatType -> "MenuListDisplayAsFormatTypes",
"ConvertFormatType" -> "MenuListConvertFormatTypes",
"DisplayAsFormatType" -> "MenuListDisplayAsFormatTypes",
"GlobalEvaluator" -> "MenuListGlobalEvaluators",
"HelpWindow" -> "MenuListHelpWindows",
"NotebookEvaluator" -> "MenuListNotebookEvaluators",
"PrintingStyleEnvironment" | PrintingStyleEnvironment ->
"PrintingStyleEnvironment",
"ScreenStyleEnvironment" | ScreenStyleEnvironment ->
ScreenStyleEnvironment,
"QuitEvaluator" -> "MenuListQuitEvaluators",
"StartEvaluator" -> "MenuListStartEvaluators",
"StyleDefinitions" | StyleDefinitions ->
"MenuListStyleDefinitions",
"CharacterEncoding" | CharacterEncoding |
ExternalDataCharacterEncoding ->
"ExternalDataCharacterEncoding",
"Style" | Style -> "Style",
"Window" -> "MenuListWindows"
};
(* ::Subsubsection::Closed:: *)
(*$autocompletionTable*)
$autocompletionTable = {
f : $autoCompletionFormats :> f,
Sequence @@ $autocompletionAliases,
s_String :> {s}
};
(* ::Subsubsection::Closed:: *)
(*autocompletionPreCompile*)
autocompletionPreCompile[v : Except[{__Rule}, _List | _?AtomQ]] :=
Replace[
Flatten[{v}, 1],
$autocompletionTable,
{1}
];
autocompletionPreCompile[o : {__Rule}] :=
Replace[o,
(s_ -> v_) :>
(
Replace[s, _Symbol :> SymbolName[s]] ->
autocompletionPreCompile[v]
),
1
];
autocompletionPreCompile[s : Except[_List], v_] :=
autocompletionPreCompile[{s -> v}];
autocompletionPreCompile[l_, v_] :=
autocompletionPreCompile@
Flatten@{
Quiet@
Check[
Thread[l -> v],
Map[l -> # &, v]
]
};
(* ::Subsubsection::Closed:: *)
(*addAutocompletions*)
addAutocompletions[
pats : {(_String -> {$autoCompletionFormats ..}) ..}] :=
If[$Notebooks &&
Internal`CachedSystemInformation["FrontEnd", "VersionNumber"] >
10.0,
FrontEndExecute@FE`Evaluate@
Map[
FEPrivate`AddSpecialArgCompletion[#]&,
pats
],
$Failed
];
addAutocompletions[pat : (_String -> {$autoCompletionFormats ..})] :=
addAutocompletions[{pat}];
addAutocompletions[a__] /; (! TrueQ@$recursionProtect) :=
Block[{$recursionProtect = True},
Replace[
addAutocompletions@autocompletionPreCompile[a],
_addAutocompletions -> $Failed
]
];
(*addAutocompletions[
addAutocompletions,
{
None,
Replace[Keys[$autocompletionAliases],
Verbatim[Alternatives][s_,___]:>s,
1
]
}
];*)
(* ::Subsection:: *)
(*Pattern Parsing*)
(* ::Subsubsection::Closed:: *)
(*reducePatterns*)
reducePatterns[p_] :=
Replace[
p,
{
Except[
_Pattern | _Optional | _Blank | _BlankSequence |
_BlankNullSequence | _PatternSequence | _OptionsPattern |
_Repeated | _RepeatedNull | _Default | _PatternTest | _Condition |
_List
] -> _
},
{2, Infinity}
] //. {
_Blank -> "Blank",
_BlankSequence -> "BlankSequence",
_BlankNullSequence -> "BlankNullSequence",
_OptionsPattern :> "OptionsPattern",
Verbatim[HoldPattern][
Verbatim[Pattern][a_, b_]
] | Verbatim[Pattern][a_, b_] :> b,
(PatternTest | Condition)[a_, b_] :> a,
Verbatim[Optional][a_, ___] :> "Optional"[a],
_Default -> "Default",
Verbatim[Repeated][_] -> "Repeated"[\[Infinity]],
Verbatim[RepeatedNull][_] -> "RepeatedNull"[\[Infinity]],
Verbatim[Repeated][_, s_] :> "Repeated"[s],
Verbatim[RepeatedNull][_, s_] :> "RepeatedNull"[s]
};
(* ::Subsubsection::Closed:: *)
(*extractArgStructureHead*)
(* ::Text:: *)
(*Done in multiple arguments for (assumed) dispatch efficiency*)
extractArgStructureHead[f_, Verbatim[HoldPattern][f_[a___][___]]]:=
HoldPattern[f[a]];
extractArgStructureHead[f_, Verbatim[HoldPattern][f_[a___][___][___]]]:=
HoldPattern[f[a]];
extractArgStructureHead[f_, Verbatim[HoldPattern][f_[a___][___][___][___]]]:=
HoldPattern[f[a]];
extractArgStructureHead[f_, Verbatim[HoldPattern][f_[a___][___][___][___][___]]]:=
HoldPattern@f[a];
extractArgStructureHead[f_, Verbatim[HoldPattern][f_[a___][___][___][___][___][___]]]:=
HoldPattern@f[a];
extractArgStructureHead[f_, Verbatim[HoldPattern][_[___, f_[a___], ___]]]:=
HoldPattern@f[a];
extractArgStructureHead[f_, Verbatim[HoldPattern][_[___, f_[a___][___], ___]]]:=
HoldPattern@f[a];
extractArgStructureHead[f_, Verbatim[HoldPattern][_[___, f_[a___][___][___], ___]]]:=
HoldPattern@f[a];
extractArgStructureHead[f_, Verbatim[HoldPattern][_[___, f_[a___][___][___][___], ___]]]:=
HoldPattern@f[a];
extractArgStructureHead[f_, Verbatim[HoldPattern][_[___, f_[a___][___][___][___][___], ___]]]:=
HoldPattern[f[a]];
extractArgStructureHead[f_, e:Except[_List]]:=e;
extractArgStructureHead~SetAttributes~{Listable, HoldFirst}
(* ::Subsubsection::Closed:: *)
(*reconstructPatterns*)
reconstructPatterns[p_] :=
Flatten[
p //. {
"Optional"[a_] :> Optional[a],
"Default" -> _.,
"OptionsPattern" -> OptionsPattern[],
"Blank" -> _,
"BlankSequence" -> __,
"BlankNullSequence" -> ___,
"Repeated"[\[Infinity]] -> Repeated[_],
"RepeatedNull"[\[Infinity]] -> RepeatedNull[_],
"Repeated"[s_] :> Repeated[_, s],
"RepeatedNull"[s_] :> RepeatedNull[_, s]
},
1
];
(* ::Subsubsection::Closed:: *)
(*argPatPartLens*)
argPathDispatch=
Dispatch[
{
_Blank -> 1 ;; 1,
_BlankSequence -> 1 ;; \[Infinity],
_BlankNullSequence -> 0 ;; \[Infinity],
Verbatim[Repeated][_] -> 1 ;; \[Infinity],
Verbatim[RepeatedNull][_] -> 0 ;; \[Infinity],
Verbatim[Repeated][_, {M_}] :> 1 ;; M,
Verbatim[RepeatedNull][_, {M_}] :> 0 ;; M,
(Repeated | RepeatedNull)[_, {M_}] :> ;; M,
(Repeated | RepeatedNull)[_, {m_, M_}] :> m ;; M,
_Optional -> 0 ;; 1,
_Default -> 0 ;; 1,
_OptionsPattern -> 0 ;; \[Infinity],
l_List :> iArgPatLens[l],
_ -> 1 ;; 1
}
];
iArgPatLens[patList_]:=
Replace[
patList,
argPathDispatch,
{1}
]
argPatPartLens[patList_] :=
Thread[ patList -> iArgPatLens[patList] ];
(* ::Subsubsection::Closed:: *)
(*argPatSimplifyDispatch*)
argPatSimplifyDispatch=
Dispatch@
{
Verbatim[Repeated][_, {1,1}]->_
}
(* ::Subsubsection::Closed:: *)
(*mergeArgPats*)
mergeArgPats[pats_, returnNum : False | True : False] :=
Module[
{
reppedPats = argPatPartLens /@ pats,
mlen,
paddies,
werkit = True,
patMaxes,
patMins,
patListPatsNums,
patChoices,
patNs,
patCho,
patListing
},
mlen = Max[Length /@ reppedPats];
paddies = PadRight[#, mlen, _. -> 0 ;; 1] & /@ reppedPats;
patListing=
MapThread[
Function[
patMins = MinimalBy[{##}, If[ListQ@#[[2]], 1, #[[2, 1]]] &];
patMaxes = MaximalBy[{##}, If[ListQ@#[[2]], 1, #[[2, 2]]] &];
patChoices = Intersection[patMins, patMaxes];
patListPatsNums = Length/@Cases[patChoices, {___, _List, ___}];
patChoices=
SortBy[patChoices,
Replace[
{
l_List:>
Depth[l]*(Max[patListPatsNums] - Length[l]),
_->0
}
]
];
patNs =
{
If[ListQ@patMins[[1, 1]], 1, patMins[[1, 2, 1]]],
If[ListQ@patMaxes[[1, 1]], 1, patMaxes[[1, 2, 2]]]
};
patCho =
If[Length@patChoices > 0,
SortBy[patChoices,
Replace[#[[1]],
{
_OptionsPattern->
0,
_RepeatedNull | _Repeated->
1,
_Optional | _Default->
2,
_->
3
}
] &
][[1, 1]],
Replace[
patNs,
{
{0, 1} -> _.,
{1, \[Infinity]} -> __,
{0, \[Infinity]} -> ___,
{m_, n_} :> Repeated[_, {m, n}]
}
]
];
If[returnNum, patCho -> patNs, patCho]
],
paddies
];
If[Length@patListing>1,
ReplaceAll[Most[patListing], _OptionsPattern->___]
~Append~
Last[patListing],
patListing
]/.argPatSimplifyDispatch
]
(* ::Subsubsection::Closed:: *)
(*generateArgPatList*)
generateArgPatList[f_, dvs_]:=
DeleteDuplicates[
reconstructPatterns /@
ReplaceAll[
reducePatterns /@ extractArgStructureHead[f, dvs],
{
(f | HoldPattern) -> List
}
]
];
generateArgPatList~SetAttributes~HoldFirst
(* ::Subsection:: *)
(*SyntaxInfo*)
(* ::Subsubsection::Closed:: *)
(*generateSIArgPat*)
generateSIArgPat[f_] :=
With[{dvs = Keys@getCodeValues[f, {DownValues, SubValues, UpValues}]},
mergeArgPats@generateArgPatList[f, dvs]
];
generateSIArgPat~SetAttributes~HoldFirst
(* ::Subsubsection::Closed:: *)
(*generateSILocVars*)
generateSILocVars[f_] :=
With[{att = Attributes[f],
dvs = Keys@getCodeValues[f, {DownValues}]},
Which[
MemberQ[att, HoldAll],
{1, Infinity},
MemberQ[att, HoldRest],
{2, Infinity},
MemberQ[att, HoldFirst],
{1}
]
];
generateSILocVars~SetAttributes~HoldFirst
(* ::Subsubsection::Closed:: *)
(*generateSIColEq*)
generateSIColEq[f_] :=
With[{dvs = Keys@getCodeValues[f, {DownValues}]},
Replace[{a_, ___} :> a]@
MaximalBy[
MinMax@Flatten@Position[#, _Equal, 1] & /@ dvs,
Apply[Subtract]@*Reverse
]
];
generateSIColEq~SetAttributes~HoldFirst
(* ::Subsubsection::Closed:: *)
(*generateSIOpNames*)
generateSIOpNames[f_] :=
ToString[#, InputForm] & /@ Keys@Options[f];
generateSIOpNames~SetAttributes~HoldFirst