forked from ocaml/Zarith
-
Notifications
You must be signed in to change notification settings - Fork 0
/
caml_z_x86_64.S
396 lines (334 loc) · 7.98 KB
/
caml_z_x86_64.S
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
/*
Assembly version for the fast path of some functions in Z:
- x86_64 target
- System 5 ABI and assembly syntax
- GNU as
This file is part of the Zarith library
http://forge.ocamlcore.org/projects/zarith .
It is distributed under LGPL 2 licensing, with static linking exception.
See the LICENSE file included in the distribution.
Copyright (c) 2010-2011 Antoine Miné, Abstraction project.
Abstraction is part of the LIENS (Laboratoire d'Informatique de l'ENS),
a joint laboratory by:
CNRS (Centre national de la recherche scientifique, France),
ENS (École normale supérieure, Paris, France),
INRIA Rocquencourt (Institut national de recherche en informatique, France).
*/
/* makes the stack non-executable. */
#ifdef Z_ELF
.section .note.GNU-stack,"",@progbits
#endif
/* helper functions */
/* **************** */
/* optional underscope prefix for symbols */
#ifdef Z_UNDERSCORE_PREFIX
#define SYMB(x) _##x
#else
#define SYMB(x) x
#endif
/* optional dot prefix for local labels */
#ifdef Z_DOT_LABEL_PREFIX
#define L(x) .L##x
#else
#define L(x) L##x
#endif
/* function prolog & epilog */
#if defined(Z_ELF)
#define FUNCTION_ALIGN 16
#endif
#if defined(Z_MACOS)
#define FUNCTION_ALIGN 4
#endif
#if defined(Z_ELF)
#define PROLOG(proc) \
.text; \
.globl SYMB(ml_as_z_##proc); \
.type SYMB(ml_as_z_##proc), @function; \
.align FUNCTION_ALIGN; \
SYMB(ml_as_z_##proc):
#define EPILOG(proc) \
.size SYMB(ml_as_z_##proc), .-SYMB(ml_as_z_##proc)
#endif
#if defined(Z_MACOS)
#define PROLOG(proc) \
.text; \
.globl SYMB(ml_as_z_##proc); \
.align FUNCTION_ALIGN; \
SYMB(ml_as_z_##proc):
#define EPILOG(proc)
#endif
/* calling C functions */
#if defined(Z_ELF)
#define C_JMP(proc) \
jmp SYMB(ml_z_##proc@PLT)
#endif
#if defined(Z_MACOS)
#define C_JMP(proc) \
jmp SYMB(ml_z_##proc)
#endif
/* operation counter */
#ifndef Z_PERF_COUNTER
#define OP
#else
#if defined(Z_ELF) || defined(Z_MACOS)
#define OP \
mov SYMB(ml_z_ops_as@GOTPCREL(%rip)), %rcx; \
addq $1, (%rcx)
#endif
#endif
/* unary arithmetics */
/* ***************** */
/* neg */
PROLOG(neg)
L(negenter):
test $1, %dil
jz L(neg)
mov %rdi, %rax
not %rax
add $3, %rax
jo L(neg)
OP
ret
L(neg):
C_JMP(neg)
EPILOG(neg)
/* abs */
PROLOG(abs)
test $1, %dil
jz L(abs)
mov %rdi, %rax
test %rdi, %rdi
jns L(abs2)
not %rax
add $3, %rax
jo L(neg)
L(abs2):
OP
ret
L(abs):
C_JMP(abs)
EPILOG(abs)
/* succ */
PROLOG(succ)
test $1, %dil
jz L(succ)
mov %rdi, %rax
add $2, %rax
jo L(succ)
OP
ret
L(succ):
C_JMP(succ)
EPILOG(succ)
/* pred */
PROLOG(pred)
test $1, %dil
jz L(pred)
mov %rdi, %rax
sub $2, %rax
jo L(pred)
OP
ret
L(pred):
C_JMP(pred)
EPILOG(pred)
/* binary arithmetics */
/* ****************** */
/* add */
PROLOG(add)
test $1, %dil
jz L(add)
test $1, %sil
jz L(add)
lea -1(%rdi), %rax
add %rsi, %rax
jo L(add)
OP
ret
L(add):
C_JMP(add)
EPILOG(add)
/* sub */
PROLOG(sub)
test $1, %dil
jz L(sub)
test $1, %sil
jz L(sub)
mov %rdi, %rax
sub %rsi, %rax
jo L(sub)
inc %rax
OP
ret
L(sub):
C_JMP(sub)
EPILOG(sub)
/* mul */
PROLOG(mul)
test $1, %dil
jz L(mul)
mov %rsi, %rcx
sar %rcx
jnc L(mul)
lea -1(%rdi), %rax
imul %rcx, %rax
jo L(mul)
inc %rax
OP
ret
L(mul):
C_JMP(mul)
EPILOG(mul)
/* div */
PROLOG(div)
mov %rsi, %rcx
cmp $-1, %rsi
/* division by -1, the only one that can overflow */
je L(negenter)
sar %rcx
jnc L(div)
jz L(div) /* division by zero */
mov %rdi, %rax
sar %rax
jnc L(div)
cqo
idiv %rcx
lea 1(%rax, %rax), %rax
OP
ret
L(div):
C_JMP(div)
EPILOG(div)
/* divexact */
PROLOG(divexact)
mov %rsi, %rcx
cmp $-1, %rsi
/* division by -1, the only one that can overflow */
je L(negenter)
sar %rcx
jnc L(divexact)
jz L(divexact) /* division by zero */
mov %rdi, %rax
sar %rax
jnc L(divexact)
cqo
idiv %rcx
lea 1(%rax, %rax), %rax
OP
ret
L(divexact):
C_JMP(divexact)
EPILOG(divexact)
/* rem */
PROLOG(rem)
mov %rdi, %rax
sar %rax
jnc L(rem)
mov %rsi, %rcx
sar %rcx
jnc L(rem)
jz L(rem) /* division by zero */
cmp $-1, %rcx
je L(remneg)
cqo
idiv %rcx
lea 1(%rdx, %rdx), %rax
OP
ret
L(remneg):
/* division by -1 */
mov $1, %eax
OP
ret
L(rem):
C_JMP(rem)
EPILOG(rem)
/* bit operations */
/* ************** */
/* not */
PROLOG(lognot)
test $1, %dil
jz L(lognot)
lea -1(%rdi), %rax
not %rax
OP
ret
L(lognot):
C_JMP(lognot)
EPILOG(lognot)
/* and */
PROLOG(logand)
mov %rdi, %rax
and %rsi, %rax
test $1, %al
jz L(logand)
OP
ret
L(logand):
C_JMP(logand)
EPILOG(logand)
/* or */
PROLOG(logor)
test $1, %dil
jz L(logor)
test $1, %sil
jz L(logor)
mov %rdi, %rax
or %rsi, %rax
OP
ret
L(logor):
C_JMP(logor)
EPILOG(logor)
/* xor */
PROLOG(logxor)
test $1, %dil
jz L(logxor)
test $1, %sil
jz L(logxor)
lea -1(%rdi), %rax
xor %rsi, %rax
OP
ret
L(logxor):
C_JMP(logxor)
EPILOG(logxor)
/* shift_left */
PROLOG(shift_left)
test $1, %dil
jz L(shift_left)
mov %esi, %ecx
sar %ecx
cmp $127, %rsi /* 63 unboxed */
jae L(shift_left)
lea -1(%rdi), %rax
mov %rax, %r8
sal %cl, %rax
mov %rax, %rdx
sar %cl, %rdx
cmp %r8, %rdx
jne L(shift_left) /* overflow */
inc %rax
OP
ret
L(shift_left):
C_JMP(shift_left)
EPILOG(shift_left)
/* shift_right */
PROLOG(shift_right)
test $1, %dil
jz L(shift_right)
mov %rsi, %rcx
mov $63, %eax
sar %rcx
js L(shift_right)
cmp %rax, %rcx /* compare second argument to 63 */
cmovae %eax, %ecx /* if above or equal, then use 63 */
mov %rdi, %rax
sar %cl, %rax
or $1, %rax
OP
ret
L(shift_right):
C_JMP(shift_right)
EPILOG(shift_right)