-
Notifications
You must be signed in to change notification settings - Fork 12
/
main.tf
223 lines (189 loc) · 8.02 KB
/
main.tf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
locals {
resource_level = var.org_integration ? "ORGANIZATION" : "PROJECT"
resource_id = var.org_integration ? var.organization_id : module.lacework_cfg_svc_account.project_id
project_id = length(var.project_id) > 0 ? var.project_id : data.google_project.selected[0].project_id
exclude_folders = length(var.folders_to_exclude) != 0
explicit_folders = length(var.folders_to_include) != 0
service_account_name = var.use_existing_service_account ? (
var.service_account_name
) : (
length(var.service_account_name) > 0 ? var.service_account_name : "${var.prefix}-${random_id.uniq.hex}"
)
service_account_json_key = jsondecode(var.use_existing_service_account ? (
base64decode(var.service_account_private_key)
) : (
base64decode(module.lacework_cfg_svc_account.private_key)
))
skip_iam_grants = var.use_existing_service_account && var.skip_iam_grants
default_project_roles = local.skip_iam_grants ? [] : [
"roles/browser",
"roles/iam.securityReviewer",
"roles/cloudasset.viewer"
]
default_organization_roles = local.skip_iam_grants ? [] : [
"roles/browser",
"roles/iam.securityReviewer",
"roles/cloudasset.viewer"
]
// if org_integration is false, project_roles = local.default_project_roles
project_roles = var.org_integration ? [] : local.default_project_roles
// if org_integration is true, organization_roles = local.default_organization_roles
organization_roles = local.skip_iam_grants ? [] : (
(var.org_integration && !(local.exclude_folders || local.explicit_folders)) ? (
local.default_organization_roles
) : (
(var.org_integration && (local.exclude_folders || local.explicit_folders)) ? (
["roles/resourcemanager.organizationViewer"]
) : (
[]
)
)
)
default_folder_roles = local.skip_iam_grants ? [] : (
(var.org_integration && (local.exclude_folders || local.explicit_folders)) ? (
[
"roles/browser",
"roles/iam.securityReviewer",
"roles/cloudasset.viewer",
google_organization_iam_custom_role.lacework_custom_organization_role.0.name
]
) : (
[]
)
)
folders = [
(var.org_integration && local.exclude_folders) ? (
setsubtract(data.google_folders.my-org-folders[0].folders[*].name, var.folders_to_exclude)
) : (
var.org_integration && local.explicit_folders) ? (
var.folders_to_include
) : (
toset([])
)]
root_projects = [
(var.org_integration && local.exclude_folders && var.include_root_projects) ? toset(data.google_projects.my-org-projects[0].projects[*].project_id) : toset([])
]
folder_roles = (var.org_integration && (local.exclude_folders || local.explicit_folders)) ? (
setproduct(local.folders[0][*], local.default_folder_roles)
) : (
[]
)
root_project_roles = (var.org_integration && var.include_root_projects) ? (
setproduct(local.root_projects[0][*], local.default_folder_roles)
) : (
[]
)
version_file = "${abspath(path.module)}/VERSION"
module_name = "terraform-gcp-config"
module_version = fileexists(local.version_file) ? file(local.version_file) : ""
}
resource "random_id" "uniq" {
byte_length = 4
}
data "google_project" "selected" {
count = length(var.project_id) > 0 ? 0 : 1
}
module "lacework_cfg_svc_account" {
source = "lacework/service-account/gcp"
version = "~> 2.0"
create = var.use_existing_service_account ? false : true
service_account_name = local.service_account_name
project_id = local.project_id
}
// Roles for a PROJECT level integration
resource "google_project_iam_custom_role" "lacework_custom_project_role" {
project = local.project_id
role_id = "lwComplianceRole_${random_id.uniq.hex}"
title = "Lacework Compliance Role"
description = "Lacework Compliance Role"
permissions = ["bigquery.datasets.get", "compute.projects.get", "pubsub.topics.get", "storage.buckets.get", "compute.sslPolicies.get"]
count = local.skip_iam_grants ? 0 : (local.resource_level == "PROJECT" ? 1 : 0)
}
resource "google_project_iam_member" "lacework_custom_project_role_binding" {
project = local.project_id
role = google_project_iam_custom_role.lacework_custom_project_role.0.name
member = "serviceAccount:${local.service_account_json_key.client_email}"
depends_on = [google_project_iam_custom_role.lacework_custom_project_role]
count = local.resource_level == "PROJECT" ? 1 : 0
}
resource "google_project_iam_member" "for_lacework_service_account" {
for_each = toset(local.project_roles)
project = local.project_id
role = each.value
member = "serviceAccount:${local.service_account_json_key.client_email}"
}
// Roles for an ORGANIZATION level integration
data "google_folders" "my-org-folders" {
count = (var.org_integration && local.exclude_folders) ? 1 : 0
parent_id = "organizations/${var.organization_id}"
}
data "google_projects" "my-org-projects" {
count = (local.exclude_folders && var.include_root_projects) ? 1 : 0
filter = "parent.id=${var.organization_id}"
}
resource "google_organization_iam_custom_role" "lacework_custom_organization_role" {
role_id = "lwOrgComplianceRole_${random_id.uniq.hex}"
org_id = var.organization_id
title = "Lacework Org Compliance Role"
description = "Lacework Org Compliance Role"
permissions = ["bigquery.datasets.get", "compute.projects.get", "pubsub.topics.get", "storage.buckets.get", "compute.sslPolicies.get"]
count = local.skip_iam_grants ? 0 : (local.resource_level == "ORGANIZATION" ? 1 : 0)
}
resource "google_organization_iam_member" "lacework_custom_organization_role_binding" {
org_id = var.organization_id
role = google_organization_iam_custom_role.lacework_custom_organization_role.0.name
member = "serviceAccount:${local.service_account_json_key.client_email}"
depends_on = [google_organization_iam_custom_role.lacework_custom_organization_role]
count = local.skip_iam_grants ? 0 : (local.resource_level == "ORGANIZATION" ? 1 : 0)
}
resource "google_organization_iam_member" "for_lacework_service_account" {
for_each = toset(local.organization_roles)
org_id = var.organization_id
role = each.value
member = "serviceAccount:${local.service_account_json_key.client_email}"
}
resource "google_folder_iam_member" "for_lacework_service_account" {
count = length(local.folder_roles)
folder = local.folder_roles[count.index][0]
role = local.folder_roles[count.index][1]
member = "serviceAccount:${local.service_account_json_key.client_email}"
}
resource "google_project_iam_member" "for_lacework_service_account_root_projects" {
count = length(local.root_project_roles)
project = local.root_project_roles[count.index][0]
role = local.root_project_roles[count.index][1]
member = "serviceAccount:${local.service_account_json_key.client_email}"
}
resource "google_project_service" "required_apis" {
for_each = var.required_config_apis
project = local.project_id
service = each.value
disable_on_destroy = false
}
# wait for X seconds for things to settle down in the GCP side
# before trying to create the Lacework external integration
resource "time_sleep" "wait_time" {
create_duration = var.wait_time
depends_on = [
module.lacework_cfg_svc_account,
google_project_service.required_apis,
google_organization_iam_member.for_lacework_service_account,
google_project_iam_member.for_lacework_service_account
]
}
resource "lacework_integration_gcp_cfg" "default" {
name = var.lacework_integration_name
resource_id = local.resource_id
resource_level = local.resource_level
credentials {
client_id = local.service_account_json_key.client_id
private_key_id = local.service_account_json_key.private_key_id
client_email = local.service_account_json_key.client_email
private_key = local.service_account_json_key.private_key
}
depends_on = [time_sleep.wait_time]
}
data "lacework_metric_module" "lwmetrics" {
name = local.module_name
version = local.module_version
}