-
Notifications
You must be signed in to change notification settings - Fork 67
/
level_set.f90
4730 lines (3535 loc) · 128 KB
/
level_set.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
!!
!! Copyright (C) 2009-2016 Johns Hopkins University
!!
!! This file is part of lesgo.
!!
!! lesgo is free software: you can redistribute it and/or modify
!! it under the terms of the GNU General Public License as published by
!! the Free Software Foundation, either version 3 of the License, or
!! (at your option) any later version.
!!
!! lesgo is distributed in the hope that it will be useful,
!! but WITHOUT ANY WARRANTY; without even the implied warranty of
!! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
!! GNU General Public License for more details.
!!
!! You should have received a copy of the GNU General Public License
!! along with lesgo. If not, see <http://www.gnu.org/licenses/>.
!!
module level_set
use types, rp => rprec
use param, only : ld, nx, ny, nz, dx, dy, dz, iBOGUS, BOGUS, path, L_x, L_y, &
vonK, lbc_mom, coord, nproc, up, down, ierr, comm, MPI_RPREC, rank, &
total_time, rank, rank_of_coord
#ifdef PPMPI
use param, only : status
use mpi
#endif
use test_filtermodule, only : filter_size
use messages
use level_set_base
implicit none
save
private
public :: level_set_forcing, level_set_init, level_set_BC, level_set_Cs
public :: level_set_global_CA
public :: level_set_smooth_vel, level_set_lag_dyn
public :: level_set_Cs_lag_dyn
public :: level_set_vel_err
character (*), parameter :: mod_name = 'level_set'
integer, parameter :: nd = 3
! #ifdef PPMPI
! ! Make sure all values (top and bottom) are less than Nz
! integer, parameter :: nphitop = 3
! integer, parameter :: nphibot = 2
! integer, parameter :: nveltop = 1
! integer, parameter :: nvelbot = 1
! integer, parameter :: ntautop = 3
! integer, parameter :: ntaubot = 2
! integer, parameter :: nFMMtop = 1
! integer, parameter :: nFMMbot = 1
! #else
! integer, parameter :: nphitop = 0
! integer, parameter :: nphibot = 0
! integer, parameter :: nveltop = 0
! integer, parameter :: nvelbot = 0
! integer, parameter :: ntautop = 0
! integer, parameter :: ntaubot = 0
! integer, parameter :: nFMMtop = 0
! integer, parameter :: nFMMbot = 0
! #endif
! !--these are the extra overlap arrays required for BC with MPI
! real (rp), dimension (ld, ny, nphitop) :: phitop
! real (rp), dimension (ld, ny, nphibot) :: phibot
! real (rp), dimension (ld, ny, nveltop) :: utop, vtop, wtop
! real (rp), dimension (ld, ny, nvelbot) :: ubot, vbot, wbot
! real (rp), dimension (ld, ny, ntautop) :: txxtop, txytop, txztop, &
! tyytop, tyztop, tzztop
! real (rp), dimension (ld, ny, ntaubot) :: txxbot, txybot, txzbot, &
! tyybot, tyzbot, tzzbot
! !--really only needed for Lagrangian SGS models
! real (rp), dimension (ld, ny, nFMMbot) :: FMMbot
! real (rp), dimension (ld, ny, nFMMtop) :: FMMtop
! real (rp) :: norm(nd, ld, ny, lbz:nz) !--normal vector
! !--may want to change so only normals
! ! near 0-set are stored
! !--experimental: desired velocities for IB method
! real (rp) :: udes(ld, ny, lbz:nz), vdes(ld, ny, lbz:nz), wdes(ld, ny, lbz:nz)
real (rp) :: phi_cutoff
real (rp) :: phi_0
!--these are the extra overlap arrays required for BC with MPI
real (rp), allocatable, dimension(:,:,:) :: phitop
real (rp), allocatable, dimension(:,:,:) :: phibot
real (rp), allocatable, dimension(:,:,:) :: utop, vtop, wtop
real (rp), allocatable, dimension(:,:,:) :: ubot, vbot, wbot
real (rp), allocatable, dimension(:,:,:) :: txxtop, txytop, txztop, &
tyytop, tyztop, tzztop
real (rp), allocatable, dimension(:,:,:) :: txxbot, txybot, txzbot, &
tyybot, tyzbot, tzzbot
!--really only needed for Lagrangian SGS models
real (rp), allocatable, dimension (:,:,:) :: FMMbot
real (rp), allocatable, dimension (:,:,:) :: FMMtop
real (rp), allocatable, dimension(:,:,:,:) :: norm !--normal vector
!--may want to change so only normals
! near 0-set are stored
!--experimental: desired velocities for IB method
real (rp), allocatable, dimension(:,:,:) :: udes, vdes, wdes
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
contains
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
subroutine level_set_init ()
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
use param, only : path, read_endian
use param, only : dx, dy, dz, lbz !--in addition to those above
use trees_pre_ls_mod, only : trees_pre_ls
implicit none
character (*), parameter :: sub_name = mod_name // '.level_set_init'
character (*), parameter :: fphi_in_base = path // 'phi.out'
character (*), parameter :: fnorm_out_base = path // 'norm.dat'
character (*), parameter :: MPI_suffix = '.c'
integer, parameter :: lun = 1
logical, parameter :: do_write_norm = .true.
character (128) :: fphi_in, fnorm_out
integer :: i, j, k
logical :: exst, opn
real (rp) :: x, y, z
!---------------------------------------------------------------------
! This is extremely kludgy. This function will write to phi.out, which will
! subsequently be read in. Future developers should fix this.
if (use_trees .and. coord == 0) then
call trees_pre_ls
endif
#ifdef PPMPI
call mpi_barrier(comm, ierr)
#endif
! First check that the grid spacing is equal in all directions
if( ( dx .ne. dy ) .or. ( dx .ne. dz ) .or. ( dy .ne. dz ) ) &
call error( sub_name, 'level set requires that dx=dy=dz -> adjust domain parameters')
#ifdef PPMPI
! Check that the buffer arrays DO NOT extent beyond neighboring processors
if( nphitop >= Nz .or. nphibot >= Nz .or. &
nveltop >= Nz .or. nvelbot >= Nz .or. &
ntautop >= Nz .or. ntaubot >= Nz .or. &
nFMMtop >= Nz .or. nFMMbot >= Nz ) &
call error( sub_name, 'Buffer array extents beyond neighboring processor')
#endif
! Allocate all arrays defined in level_set
! !--these are the extra overlap arrays required for BC with MPI
allocate( phitop(ld, ny, nphitop) )
allocate( phibot(ld, ny, nphibot) )
allocate( utop(ld, ny, nveltop), vtop(ld, ny, nveltop), wtop(ld, ny, nveltop) )
allocate( ubot(ld, ny, nvelbot), vbot(ld, ny, nvelbot), wbot(ld, ny, nvelbot) )
allocate( txxtop(ld, ny, ntautop), &
txytop(ld, ny, ntautop), &
txztop(ld, ny, ntautop), &
tyytop(ld, ny, ntautop), &
tyztop(ld, ny, ntautop), &
tzztop(ld, ny, ntautop) )
allocate( txxbot(ld, ny, ntaubot), &
txybot(ld, ny, ntaubot), &
txzbot(ld, ny, ntaubot), &
tyybot(ld, ny, ntaubot), &
tyzbot(ld, ny, ntaubot), &
tzzbot(ld, ny, ntaubot) )
! !--really only needed for Lagrangian SGS models
allocate( FMMbot(ld, ny, nFMMbot) )
allocate( FMMtop(ld, ny, nFMMtop) )
allocate( norm(nd, ld, ny, lbz:nz) )!--normal vector
! !--may want to change so only normals
! ! near 0-set are stored
! !--experimental: desired velocities for IB method
if( vel_BC ) allocate( udes(ld, ny, lbz:nz), &
vdes(ld, ny, lbz:nz), &
wdes(ld, ny, lbz:nz) )
inquire (unit=lun, exist=exst, opened=opn)
if (.not. exst) call error (sub_name, 'lun =', lun, 'does not exist')
if (opn) call error (sub_name, 'lun =', lun, 'is already open')
#ifdef PPMPI
write (fphi_in, '(a,a,i0)') trim (fphi_in_base), MPI_suffix, coord
#else
fphi_in = trim (fphi_in_base)
#endif
inquire (file=fphi_in, exist=exst, opened=opn)
if (.not. exst) call error (sub_name, 'file ' // fphi_in // ' does not exist')
if (opn) call error (sub_name, 'file ' // fphi_in // ' is aleady open')
open (lun, file=fphi_in, form='unformatted', action='read', position='rewind', convert=read_endian)
read (lun) phi(:, :, lbz:nz)
!--phi(:, :, 0) will be BOGUS at coord == 0
!--for now, phi(:, :, nz) will be valid at coord = nproc - 1
close (lun)
call mesg (sub_name, 'level set function initialized')
!--calculate the normal
!--provides 0:nz-1, except at coord = 0 it provides 1:nz-1
call fill_norm ()
if (do_write_norm) then
#ifdef PPMPI
write (fnorm_out, '(a,a,i0)') trim (fnorm_out_base), MPI_suffix, coord
#else
fnorm_out = trim (fnorm_out_base)
#endif
!--output normal in ascii, for checking purposes
!--recall nz-level is BOGUS
open (lun, file=fnorm_out, action='write')
write (lun, '(a)') 'variables = "x" "y" "z" "n1" "n2" "n3"'
write (lun, '(3(a,i0))') 'zone, f=point, i=', nx, ', j=', ny, ', k=', nz-1
do k = 1, nz-1
z = (k - 0.5_rp) * dz
do j = 1, ny
y = (j - 1) * dy
do i = 1, nx
x = (i - 1) * dx
write (lun, '(6(1x,es12.5))') x, y, z, norm(:, i, j, k)
end do
end do
end do
close (lun)
end if
end subroutine level_set_init
!**********************************************************************
subroutine level_set_vel_err()
!**********************************************************************
!
! This subroutine computes the error in the final velocity field (u^{m+1})
! with respect to the desired IBM velocity (here zero). The averaged
! value is written to file
!
use types, only : rprec
use param, only : nx, ny, nz, total_time
use sim_param, only : u, v, w
#ifdef PPMPI
use mpi
use param, only : up, down, ierr, MPI_RPREC, status, comm, coord
#endif
implicit none
character (*), parameter :: sub_name = mod_name // '.level_set_vel_err'
character(*), parameter :: fname_write = path // 'output/level_set_vel_err.dat'
integer :: i,j,k
integer :: uv_err_navg, w_err_navg
real(rprec) :: u_err, v_err, w_err
#ifdef PPMPI
real(rprec) :: u_err_global, v_err_global, w_err_global
#endif
integer :: fid
! Initialize values
uv_err_navg = 0
w_err_navg = 0
u_err = 0._rprec
v_err = 0._rprec
w_err = 0._rprec
! Sum over bottom plane
k=1
do j=1, ny
do i=1, nx
if( phi(i,j,k) <= 0._rprec ) then
uv_err_navg = uv_err_navg + 1
u_err = u_err + abs( u(i,j,k) )
v_err = v_err + abs( v(i,j,k) )
endif
enddo
enddo
! Sum over rest of planes
do k=2, nz-1
do j=1, ny
do i=1, nx
if( phi(i,j,k) <= 0._rprec ) then
uv_err_navg = uv_err_navg + 1
u_err = u_err + abs( u(i,j,k) )
v_err = v_err + abs( v(i,j,k) )
endif
if( phi(i,j,k) + phi(i,j,k-1) <= 0._rprec ) then
w_err_navg = w_err_navg + 1
w_err = w_err + abs( w(i,j,k) )
endif
enddo
enddo
enddo
if( uv_err_navg == 0 ) then
u_err = 0._rprec
v_err = 0._rprec
else
u_err = u_err / uv_err_navg
v_err = v_err / uv_err_navg
endif
if( w_err_navg == 0 ) then
w_err = 0._rprec
else
w_err = w_err / w_err_navg
endif
#ifdef PPMPI
call mpi_reduce (u_err, u_err_global, 1, MPI_RPREC, MPI_SUM, 0, comm, ierr)
call mpi_reduce (v_err, v_err_global, 1, MPI_RPREC, MPI_SUM, 0, comm, ierr)
call mpi_reduce (w_err, w_err_global, 1, MPI_RPREC, MPI_SUM, 0, comm, ierr)
if( rank == 0 ) then
u_err = u_err_global / nproc
v_err = v_err_global / nproc
w_err = w_err_global / nproc
open(newunit=fid, file=fname_write, status='unknown', form='formatted', &
position='append')
write(fid,*) total_time, sqrt( u_err**2 + v_err**2 + w_err**2 )
close(fid)
endif
#else
open(newunit=fid, file=fname_write, status='unknown', form='formatted', &
position='append')
write(fid,*) total_time, sqrt( u_err**2 + v_err**2 + w_err**2 )
close(fid)
#endif
return
end subroutine level_set_vel_err
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!--sets Cs2 to epsilon inside solid
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
subroutine level_set_Cs_lag_dyn ()
use sgs_param, only : Cs_opt2
implicit none
character (*), parameter :: sub_name = mod_name // '.level_set_Cs_lag_dyn'
real (rp), parameter :: eps = 100._rp * epsilon (0._rp)
integer :: i, j, k
integer :: s
real (rp) :: phix
!---------------------------------------------------------------------
do k = 1, nz
if ( (coord == 0) .and. (k == 1) ) then
s = 0
else
s = 1
end if
do j = 1, ny
do i = 1, nx
phix = 0.5_rp * (phi(i, j, k) + phi(i, j, k - s))
if (phix < 0._rp) Cs_opt2(i, j, k) = eps
end do
end do
end do
end subroutine level_set_Cs_lag_dyn
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!--see trees_BC for reference implementation
!--Sij are on w-nodes
!--F_LM, F_MM on w-nodes
! * smoothes u, v, w, Sij in solid
! * zeroes F_LM inside solid
! * applies neumann condition on F_MM at solid surface
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
subroutine level_set_lag_dyn (S11, S12, S13, S22, S23, S33)
use param, only: lbz
use sim_param, only : u, v, w
implicit none
real (rp) :: S11(ld, ny, nz), S12(ld, ny, nz), S13(ld, ny, nz), &
S22(ld, ny, nz), S23(ld, ny, nz), S33(ld, ny, nz)
character (*), parameter :: sub_name = mod_name // '.level_set_lag_dyn'
logical, parameter :: lag_dyn_modify_beta = .true.
real (rp) :: phi_c
!---------------------------------------------------------------------
!--part 1: smooth variables
phi_c = 0._rp
call smooth (phi_c, lbz, u)
call smooth (phi_c, lbz, v)
call smooth (phi_c, lbz, w, 'w')
call smooth (phi_c, 1, S11, 'w')
call smooth (phi_c, 1, S12, 'w')
call smooth (phi_c, 1, S13, 'w')
call smooth (phi_c, 1, S22, 'w')
call smooth (phi_c, 1, S23, 'w')
call smooth (phi_c, 1, S33, 'w')
!--part 2: zero F_LM
call zero_F_LM ()
!--part 3: neumann condition on F_MM
call neumann_F_MM ()
!--part 4 (optional): modify beta
if (lag_dyn_modify_beta) call modify_beta ()
end subroutine level_set_lag_dyn
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
subroutine modify_beta ()
use sgs_param, only : beta
implicit none
character (*), parameter :: sub_name = mod_name // '.modify_beta'
real (rp), parameter :: c1 = 0.65_rp
real (rp), parameter :: c2 = 0.7_rp
integer :: i, j, k
integer :: s
real (rp) :: delta
real (rp) :: phix
real (rp) :: dmin
real (rp) :: z
!---------------------------------------------------------------------
delta = filter_size * (dx * dy * dz)**(1._rp / 3._rp)
do k = 1, nz
if ( (coord == 0) .and. (k == 1) ) then
s = 0
else
s = 1
end if
do j = 1, ny
do i = 1, nx
phix = 0.5_rp * (phi(i, j, k) + phi(i, j, k-s))
if (phix > 0._rp) then
if (lbc_mom == 0) then
! Stress free
dmin = phix
else
z = (k - 1) * dz
dmin = min (z, phix)
end if
beta(i, j, k) = 1._rp - c1 * exp (-c2 * dmin / delta)
end if
end do
end do
end do
end subroutine modify_beta
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!--requires F_MM to be valid on 1:nz (interp_F_MM does)
!--only applies neumann condition to 1:nz-1 though, so additional
! sync between nz and 1' is needed
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
subroutine neumann_F_MM ()
use sgs_param, only : F_MM
implicit none
character (*), parameter :: sub_name = mod_name // '.neumann_F_MM'
integer, parameter :: tag = 1200
integer :: i, j, k
integer :: s
real (rp) :: phix
real (rp) :: phi1, phi2 !--take action when phi1 < phix < phi2
real (rp) :: dphi
real (rp) :: F_MM_xp
real (rp) :: x(nd), xp(nd)
real (rp) :: n_hat(nd)
!---------------------------------------------------------------------
phi1 = -sqrt (dx**2 + dy**2 + dz**2)
phi2 = 0._rp
!--for now dphi does not depend on normal
dphi = sqrt (dx**2 + dy**2 + dz**2)
#ifdef PPMPI
call mpi_sync_F_MM ()
#endif
do k = 1, nz - 1
if ( (coord == 0) .and. (k == 1) ) then
s = 0 !--u-nodes
else
s = 1 !--w-nodes
end if
do j = 1, ny
do i = 1, nx
phix = 0.5_rp * (phi(i, j, k) + phi(i, j, k - s))
if ((phi1 < phix) .and. (phix < phi2)) then
x = (/ (i - 1) * dx, (j - 1) * dy, (k - 0.5_rp * (1+s)) * dz /)
!--select u/w node
n_hat = 0.5_rp * (norm(:, i, j, k) + norm(:, i, j, k - s))
!--dphi depends on normal? should be > phi2 - phi1
xp = x + dphi * n_hat
call interp_scal (1, F_MM, nFMMbot, FMMbot, nFMMtop, FMMtop, &
xp, F_MM_xp, 'w')
F_MM(i, j, k) = F_MM_xp
end if
end do
end do
end do
#ifdef PPMPI
!--make F_MM valid at 1:nz (as in core code) by syncing nz to 1'
!--not sure this is crucial
call mpi_sendrecv (F_MM(1, 1, 1), ld*ny, MPI_RPREC, down, tag+1, &
F_MM(1, 1, nz), ld*ny, MPI_RPREC, up, tag+1, &
comm, status, ierr)
#endif
#ifdef PPMPI
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
contains
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
subroutine mpi_sync_F_MM ()
implicit none
integer, parameter :: tag = 1100
integer :: datasize
integer :: kstart
!-------------------------------------------------------------------
datasize = ld * ny * nFMMtop
kstart = 2
call mpi_sendrecv (F_MM(1, 1, kstart), datasize, MPI_RPREC, down, tag+1, &
FMMtop(1, 1, 1), datasize, MPI_RPREC, up, tag+1, &
comm, status, ierr)
datasize = ld * ny * nFMMbot
kstart = nz - nFMMbot !--F_MM is has lbz = 1
call mpi_sendrecv (F_MM(1, 1, kstart), datasize, MPI_RPREC, up, tag+4, &
FMMbot(1, 1, 1), datasize, MPI_RPREC, down, tag+4, &
comm, status, ierr)
end subroutine mpi_sync_F_MM
#endif
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
end subroutine neumann_F_MM
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!--zeros F_LM for phi < phi_F_LM
!--only operates on 1:nz-1, MAY NEED 1:nz for complete consistency!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
subroutine zero_F_LM ()
use sgs_param, only : F_LM
implicit none
character (*), parameter :: sub_name = mod_name // '.zero_F_LM'
integer, parameter :: tag = 1300
integer :: i, j, k
integer :: s
real (rp) :: phix
real (rp) :: phi_F_LM
!---------------------------------------------------------------------
!phi_F_LM = 0._rp
phi_F_LM = filter_size * dx !--experimental
do k = 1, nz - 1
if ( (coord == 0) .and. (k == 1) ) then
s = 0 !--use phi at u-node
else
s = 1
end if
do j = 1, ny
do i = 1, nx
phix = 0.5_rp * (phi(i, j, k) + phi(i, j, k-s))
if (phix < phi_F_LM) F_LM(i, j, k) = 0._rp
end do
end do
end do
#ifdef PPMPI
!--make F_LM valid at 1:nz (as in core code) by syncing nz to 1'
!--not sure this is crucial
!--probably can change above loop to 1:nz, since phi is valid there
call mpi_sendrecv (F_LM(1, 1, 1), ld*ny, MPI_RPREC, down, tag+1, &
F_LM(1, 1, nz), ld*ny, MPI_RPREC, up, tag+1, &
comm, status, ierr)
#endif
end subroutine zero_F_LM
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
subroutine modify_dutdn (i, j, k, tau, phix, x_hat, y_hat, z_hat, node)
use sim_param, only : dudx, dudy, dudz, &
dvdx, dvdy, dvdz, &
dwdx, dwdy, dwdz
implicit none
integer, intent (in) :: i, j, k
real (rp), intent (in) :: tau
real (rp), intent (in) :: phix
real (rp), intent (in) :: x_hat(nd), y_hat(nd), z_hat(nd)
character (*), intent (in), optional :: node !--'u' or 'w'
character (*), parameter :: sub_name = mod_name // '.modify_dutdn'
logical :: unode
real (rp) :: A(nd, nd)
real (rp) :: G(nd, nd), Gp(nd, nd)
real (rp) :: grad
real (rp) :: phi_min
!---------------------------------------------------------------------
A(1, :) = x_hat
A(2, :) = y_hat
A(3, :) = z_hat
if (present (node)) then
select case (node)
case ('u'); unode = .true.
case ('w'); unode = .false.
case default; call error (sub_name, 'invalid node = ' // node)
end select
else !--assume u-node
unode = .true.
end if
if (unode) then
G(:, 1) = (/ dudx(i, j, k), dvdx(i, j, k), &
0.5_rp * (dwdx(i, j, k) + dwdx(i, j, k + 1)) /)
G(:, 2) = (/ dudy(i, j, k), dvdy(i, j, k), &
0.5_rp * (dwdy(i, j, k) + dwdy(i, j, k + 1)) /)
G(:, 3) = (/ 0.5_rp * (dudz(i, j, k) + dudz(i, j, k + 1)), &
0.5_rp * (dvdz(i, j, k) + dvdz(i, j, k + 1)), &
dwdz(i, j, k) /)
else !--w-node
G(:, 1) = (/ 0.5_rp * (dudx(i, j, k) + dudx(i, j, k - 1)), &
0.5_rp * (dvdx(i, j, k) + dvdx(i, j, k - 1)), &
dwdx(i, j, k) /)
G(:, 2) = (/ 0.5_rp * (dudy(i, j, k) + dudy(i, j, k - 1)), &
0.5_rp * (dvdy(i, j, k) + dvdy(i, j, k - 1)), &
dwdy(i, j, k) /)
G(:, 3) = (/ dudz(i, j, k), dvdz(i, j, k), &
0.5_rp * (dwdz(i, j, k) + dwdz(i, j, k - 1)) /)
end if
!--calculate Gp: gradient in primed (rotated) coordinates
Gp = matmul ( A, matmul (G, transpose (A)) )
!--set the value of dut/dn to be consistent w/log-law
if (phi_cutoff_is_set) then
phi_min = (0.1_rp * phi_cutoff) !--experimental
else
call error (sub_name, 'trying to use unset phi_cutoff')
end if
grad = sqrt (abs (tau)) / (vonK * (max (phi_min, phix) + zo_level_set))
Gp(1, 3) = grad
!--rotate back to x, y, z frame
G = matmul ( transpose (A), matmul (Gp, A))
!--still not sure if this is right: only re-assign u-node components
! on u-nodes, same with w
if (unode) then
dudx(i, j, k) = G(1, 1)
dvdx(i, j, k) = G(2, 1)
dudy(i, j, k) = G(1, 2)
dvdy(i, j, k) = G(2, 2)
dwdz(i, j, k) = G(3, 3)
else
dudz(i, j, k) = G(1, 3)
dvdz(i, j, k) = G(2, 3)
dwdx(i, j, k) = G(3, 1)
dwdy(i, j, k) = G(3, 2)
end if
end subroutine modify_dutdn
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!--this is supposed to replace extrap_tau
!--this avoids using fit3
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
subroutine extrap_tau_simple ()
use param, only : jt_total
use sim_param, only : u, v, w, txx, txy, txz, tyy, tyz, tzz
implicit none
character (*), parameter :: sub_name = mod_name // '.extrap_tau_simple'
character (*), parameter :: fprefix = path // 'output/extrap_tau_simple.'
character (*), parameter :: fmta3r = '(a,3(es12.5,1x))'
character (*), parameter :: fmta3i = '(a,3(i0,1x))'
integer, parameter :: noutput = 200
integer, parameter :: lun = 1
logical, parameter :: use_output = .false.
real (rp), parameter :: eps = 100._rp * epsilon (0._rp)
character (128) :: fname
integer :: i, j, k
!--experiment to reduce time spent on looping over fluid pts
!integer, save :: imn = 1, imx = nx, jmn = 1, jmx = ny
integer :: imn, imx, jmn, jmx
integer :: imn_used, imx_used, jmn_used, jmx_used
integer :: nbad
integer :: kmn
logical :: output
logical :: exst, opn
real (rp) :: phi_c, phi_x
real (rp) :: dphi0, dphi
real (rp) :: phi1, phi2
real (rp) :: txx1, txy1, txz1, tyy1, tyz1, tzz1
real (rp) :: txx2, txy2, txz2, tyy2, tyz2, tzz2
real (rp) :: wgt
real (rp) :: x(nd), x1(nd), x2(nd)
real (rp) :: n_hat(nd)
!---------------------------------------------------------------------
! Set default values
imn = 1
imx = nx
jmn = 1
jmx = ny
if (use_output) then
if (modulo (jt_total, noutput) == 0) then
output = .true.
write (fname, '(a,i6.6,a)') trim (fprefix), jt_total, '.dat'
inquire (unit=lun, exist=exst, opened=opn)
if (exst .and. (.not. opn)) then
open (lun, file=fname)
else
call error (sub_name, 'problem opening file')
end if
else
output = .false.
end if
else
output = .false.
end if
if (phi_cutoff_is_set) then
phi_c = phi_cutoff
else
call error (sub_name, 'trying to use uninitialized phi_cutoff')
end if
if (.not. phi_0_is_set) then
call error (sub_name, 'trying to use uninitialized phi_0')
end if
dphi0 = filter_size * dx !--experiment
if (output) then
write (lun, *) 'phi_c = ', phi_c
write (lun, *) 'phi_0 = ', phi_0
write (lun, *) 'dphi = ', dphi
end if
! initial values for _used variables
! setting to non-previously used values
imn_used = nx
imx_used = 1
jmn_used = ny
jmx_used = 1
nbad = 0
if (output) write (lun, *) 'u-node pass'
!--u-node pass
do k = 1, nz - 1
do j = jmn, jmx
do i = imn, imx
phi_x = phi(i, j, k)
if ((-phi_c <= phi_x) .and. (phi_x < phi_0)) then
! Find bounding box for all "banded" points"
imn_used = min (imn_used, i)
imx_used = max (imx_used, i)
jmn_used = min (jmn_used, j)
jmx_used = max (jmx_used, j)
x = (/ (i - 1) * dx, (j - 1) * dy, (k - 0.5_rp) * dz /)
n_hat = norm(:, i, j, k)
dphi = dphi0
x1 = x + dphi * n_hat !--this pt is supposed to be in fluid
!--this means dphi >= phi_c
!--check phi(x1) >= 0
call interp_phi (x1, phi1)
if (phi1 < phi_0) then
!--try a larger dphi--experimental
dphi = 1.5_rp * dphi
x1 = x + dphi * n_hat
call interp_phi (x1, phi1)
if (phi1 < phi_0) then
!--probably here because of the way the normal (phi)
! inside the trees are calculated: its not a true
! signed distance function, due to the complex internal
! geometry
!--not sure how to set tau here: for now set to 0._rp
nbad = nbad + 1
!call mesg (sub_name, 'bad point (u): ', (/ i, j, k /))
txx(i, j, k) = 0._rp
txy(i, j, k) = 0._rp
txz(i, j, k) = 0._rp
tyy(i, j, k) = 0._rp
tyz(i, j, k) = 0._rp
tzz(i, j, k) = 0._rp
cycle !--onto next point
!call mesg (sub_name, 'at u-node (i, j, k) =', (/ i, j, k /))
!call mesg (sub_name, 'phi_x =', phi_x)
!call mesg (sub_name, 'x =', x)
!call mesg (sub_name, 'n_hat =', n_hat)
!call mesg (sub_name, 'dphi =', dphi)
!call mesg (sub_name, 'x1 =', x1)
!call mesg (sub_name, 'phi_0 =', phi_0)
!call mesg (sub_name, 'phi1 =', phi1)
!call error (sub_name, 'phi1 < phi_0')
end if
end if
!if (phi1 < 0._rp) call error (sub_name, 'phi1 =', phi1)
x2 = x1 + dphi * n_hat !--this is supposed to be further into fluid
! than x1
!--problem for highly wrinkled surface
!--check phi(x2) >= 0
call interp_phi (x2, phi2)
!--calculate tij1, for use in extrapolation
call interp_tij_u (x1, txx1, txy1, tyy1, tzz1)
!call interp_scal (txx, x1, txx1)
!call interp_scal (txy, x1, txy1)
!call interp_scal (tyy, x1, tyy1)
!call interp_scal (tzz, x1, tzz1)
!--calculate tij2, for use in extrapolation
call interp_tij_u (x2, txx2, txy2, tyy2, tzz2)
!call interp_scal (txx, x2, txx2)
!call interp_scal (txy, x2, txy2)
!call interp_scal (tyy, x2, tyy2)
!call interp_scal (tzz, x2, tzz2)
!--now extrapolate
!--simple linear extrap, for now
!wgt = (phi2 - phi1) / (phi2 - phi_x)
!--since the two dphi steps are equal, the wgt is 0.5
wgt = 0.5_rp
!--the way we define the phis right now, expect wgt ~= 0.5
!--its a problem is wgt is smaller than say 0.25
!if (wgt < 0.25_rp) then
! write (msg, *) 'extrapolation weight too small (u-node)', n_l, &
! 'coord = ', coord, n_l, &
! 'wgt = ', wgt, n_l, &
! 'i, j, k = ', i, j, k, n_l, &
! 'x = ', x, n_l, &
! 'x1 = ', x1, n_l, &
! 'x2 = ', x2, n_l, &
! 'phi = ', phi_x, n_l, &
! 'phi1 = ', phi1, n_l, &
! 'phi2 = ', phi2, n_l, &
! 'n_hat = ', n_hat
! call error (sub_name, msg)
!end if