-
Notifications
You must be signed in to change notification settings - Fork 21
/
OPML.pm
executable file
·2028 lines (1653 loc) · 50.8 KB
/
OPML.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
package Plugins::Spotty::OPML;
use strict;
BEGIN {
use Exporter::Lite;
our @EXPORT_OK = qw(IMG_PLAYLIST);
}
use URI::Escape qw(uri_escape_utf8);
use Plugins::Spotty::AccountHelper;
use Plugins::Spotty::API;
use Slim::Menu::BrowseLibrary;
use Slim::Menu::GlobalSearch;
use Slim::Utils::Cache;
use Slim::Utils::Log;
use Slim::Utils::Prefs;
use Slim::Utils::Strings qw(string cstring);
use constant CAN_EXTID => (Slim::Utils::Versions->compareVersions($::VERSION, '8.0.0') >= 0);
use constant IMG_TRACK => '/html/images/cover.png';
use constant IMG_HOME => 'plugins/Spotty/html/images/home.png';
use constant IMG_ALBUM => 'plugins/Spotty/html/images/album.png';
use constant IMG_COMPILATION => 'plugins/Spotty/html/images/compilation.png';
use constant IMG_PODCAST => 'plugins/Spotty/html/images/podcasts.png';
use constant IMG_PLAYLIST => 'plugins/Spotty/html/images/playlist.png';
use constant IMG_COLLABORATIVE => 'plugins/Spotty/html/images/playlist-collab.png';
use constant IMG_SEARCH => 'plugins/Spotty/html/images/search.png';
use constant IMG_ACCOUNT => 'plugins/Spotty/html/images/account.png';
use constant IMG_ARTIST => 'plugins/Spotty/html/images/artist.png';
use constant IMG_FOLLOW_ARTIST => 'plugins/Spotty/html/images/followartist.png';
use constant IMG_TOPTRACKS => 'plugins/Spotty/html/images/toptracks.png';
use constant IMG_NEWS => 'plugins/Spotty/html/images/news.png';
use constant IMG_GENRES => 'plugins/Spotty/html/images/genres.png';
use constant IMG_INBOX => 'plugins/Spotty/html/images/inbox.png';
use constant IMG_TRANSFER => 'plugins/Spotty/html/images/transfer.png';
use constant IMG_SONG => 'plugins/Spotty/html/images/song.png';
use constant IMG_RADIO => 'plugins/Spotty/html/images/radio.png';
# must delay this import, as it's using above export
use Plugins::Spotty::PlaylistFolders;
use constant MAX_RECENT => 50;
my $prefs = preferences('plugin.spotty');
my $serverPrefs = preferences('server');
my $log = logger('plugin.spotty');
my $cache = Slim::Utils::Cache->new();
my %topuri = (
AT => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbKNHh6NIXu36',
AU => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbJPcfkRz0wJ0',
BE => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbJNSeeHswcKB',
CA => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbKj23U1GF4IR',
CH => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbJiyhoAPEfMK',
DE => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbJiZcmkrIHGU',
DK => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbL3J0k32lWnN',
ES => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbNFJfN1Vw8d9',
FI => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbMxcczTSoGwZ',
FR => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbIPWwFssbupI',
GB => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbLnolsZ8PSNw',
IT => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbIQnj7RRhdSX',
NL => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbKCF6dqVpDkS',
NO => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbJvfa0Yxg7E7',
NZ => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbM8SIrkERIYl',
SE => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbLoATJ81JYXz',
US => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbLRQDuF5jeBp',
XX => 'spotify:user:spotifycharts:playlist:37i9dQZEVXbMDoHDwVN2tF', # fallback "Top 100 on Spotify"
);
my $nextNameCheck = 0;
sub init {
Slim::Menu::TrackInfo->registerInfoProvider( spotty => (
after => 'top',
func => \&trackInfoMenu,
) );
Slim::Menu::ArtistInfo->registerInfoProvider( spotty => (
after => 'top',
func => \&artistInfoMenu,
) );
Slim::Menu::AlbumInfo->registerInfoProvider( spotty => (
after => 'top',
func => \&albumInfoMenu,
) );
Slim::Menu::GlobalSearch->registerInfoProvider( spotty => (
func => sub {
my ( $client, $tags ) = @_;
return {
name => cstring($client, Plugins::Spotty::Plugin::getDisplayName()),
items => [ map { delete $_->{image}; $_ } @{_searchItems($client, $tags->{search})} ],
};
},
) );
if ( Slim::Utils::PluginManager->isEnabled('Slim::Plugin::OnlineLibrary::Plugin') ) {
require Slim::Plugin::OnlineLibrary::BrowseArtist;
Slim::Plugin::OnlineLibrary::BrowseArtist->registerBrowseArtistItem( spotify => sub {
my ( $client ) = @_;
return {
name => cstring($client, 'BROWSE_ON_SERVICE', 'Spotify'),
type => 'link',
icon => Plugins::Spotty::Plugin->_pluginDataFor('icon'),
url => \&browseArtistMenu,
};
} );
main::INFOLOG && $log->is_info && $log->info("Successfully registered BrowseArtist handler for Spotify");
}
# |requires Client
# | |is a Query
# | | |has Tags
# | | | |Function to call
# C Q T F
Slim::Control::Request::addDispatch(['spotty','recentsearches'],
[0, 0, 1, \&_recentSearchesCLI]
);
# enforce initial refresh of users' display names
$cache->remove('spotty_got_names');
}
sub handleFeed {
my ($client, $cb, $args) = @_;
if (!$client) {
$cb->({
items => [{
name => string('PLUGIN_SPOTTY_NO_PLAYER_CONNECTED'),
type => 'text'
}]
});
return;
}
elsif (!Slim::Networking::Async::HTTP->hasSSL()) {
$cb->({
items => [{
name => cstring($client, 'PLUGIN_SPOTTY_MISSING_SSL'),
type => 'textarea'
}]
});
return;
}
elsif ( !Plugins::Spotty::AccountHelper->hasCredentials() || !Plugins::Spotty::AccountHelper->getAccount($client) ) {
$cb->({
items => [{
name => cstring($client, 'PLUGIN_SPOTTY_NOT_AUTHORIZED') . "\n" . cstring($client, 'PLUGIN_SPOTTY_NOT_AUTHORIZED_HINT'),
type => 'textarea'
}]
});
return;
}
# if there's no account assigned to the player, just pick one - we should never get here...
elsif ( !Plugins::Spotty::AccountHelper->getCredentials($client) ) {
selectAccount($client, $cb, $args);
return;
}
# update users' display names every now and then
if ( Plugins::Spotty::AccountHelper->hasMultipleAccounts() && $nextNameCheck < time ) {
foreach ( @{ Plugins::Spotty::AccountHelper->getSortedCredentialTupels() } ) {
my ($name, $id) = each %{$_};
Plugins::Spotty::AccountHelper->getName($client, $name);
}
$nextNameCheck = time() + 3600;
}
my $spotty = Plugins::Spotty::Plugin->getAPIHandler($client);
$spotty->featuredPlaylists( sub {
my ($lists, $message) = @_;
# if we didn't get any playlists nor token, then something's wrong
if ( !($lists && ref $lists && scalar @$lists && $message) ) {
$log->warn('Failed to get featured playlists and/or token - do not continue');
$cb->({
items => [{
name => cstring($client, 'PLUGIN_SPOTTY_ERROR_NO_ACCESS_TOKEN') . "\n" . cstring($client, 'PLUGIN_SPOTTY_NOT_AUTHORIZED_HINT'),
type => 'textarea'
}]
});
return;
}
# Build main menu structure
my $items = [];
if ( hasRecentSearches() ) {
push @{$items}, {
name => cstring($client, 'SEARCH'),
type => 'link',
image => IMG_SEARCH,
url => \&recentSearches,
};
}
else {
push @{$items}, {
name => cstring($client, 'SEARCH'),
type => 'search',
image => IMG_SEARCH,
url => \&search,
};
}
push @{$items}, {
name => cstring($client, 'PLUGIN_SPOTTY_WHATS_NEW'),
type => 'link',
image => IMG_NEWS,
url => \&whatsNew
},
{
name => cstring($client, 'PLUGIN_SPOTTY_TOP_TRACKS'),
type => 'playlist',
image => IMG_TOPTRACKS,
url => \&playlist,
passthrough => [{
uri => $topuri{$spotty->country()} || $topuri{XX}
}]
},
{
name => cstring($client, 'PLUGIN_SPOTTY_GENRES_MOODS'),
type => 'link',
image => IMG_GENRES,
url => \&categories
};
if ( $message && $lists && ref $lists && scalar @$lists ) {
push @$items, {
name => $message,
image => IMG_INBOX,
items => playlistList($client, $lists)
};
}
my $personalItems = [{
name => cstring($client, 'ALBUMS'),
type => 'link',
image => IMG_ALBUM,
url => \&myAlbums,
},{
name => cstring($client, 'ARTISTS'),
type => 'link',
image => IMG_ARTIST,
url => \&myArtists
},{
name => cstring($client, 'PLAYLISTS'),
type => 'link',
image => IMG_PLAYLIST,
url => \&playlists
}];
if ( Plugins::Spotty::Helper->getCapability('podcasts') ) {
push @$personalItems, {
name => cstring($client, 'PLUGIN_SPOTTY_SHOWS'),
type => 'link',
image => IMG_PODCAST,
url => \&shows
};
}
# only give access to the tracks list if the user is using his own client ID
if ( _enableAdvancedFeatures() ) {
unshift @$personalItems, {
name => cstring($client, 'PLUGIN_SPOTTY_SONGS_LIST'),
type => 'playlist',
image => IMG_SONG,
url => \&mySongs,
}
}
my $homeItem = {
name => cstring($client, 'PLUGIN_SPOTTY_HOME'),
type => 'link',
image => IMG_HOME,
url => \&home,
};
if ( !$prefs->get('accountSwitcherMenu') && Plugins::Spotty::AccountHelper->hasMultipleAccounts() ) {
my $credentials = Plugins::Spotty::AccountHelper->getAllCredentials();
foreach my $name ( sort {
lc($a) cmp lc($b)
} keys %$credentials ) {
push @$items, {
name => Plugins::Spotty::AccountHelper->getDisplayName($name),
items => [ map {{
name => $_->{name},
type => $_->{type},
image => $_->{image},
url => \&_withAccount,
passthrough => [{
name => $name,
cb => $_->{url}
}]
}} $homeItem, @$personalItems ],
image => IMG_ACCOUNT,
};
}
}
else {
unshift @$items, $homeItem;
push @$items, @$personalItems;
}
push @$items, {
name => cstring($client, 'PLUGIN_SPOTTY_TRANSFER'),
type => 'link',
image => IMG_TRANSFER,
url => \&transferPlaylist
};
if ( $prefs->get('accountSwitcherMenu') && Plugins::Spotty::AccountHelper->hasMultipleAccounts() ) {
push @$items, {
name => cstring($client, 'PLUGIN_SPOTTY_ACCOUNT'),
items => [{
name => Plugins::Spotty::AccountHelper->getDisplayName($spotty->username),
type => 'text'
},{
name => cstring($client, 'PLUGIN_SPOTTY_SELECT_ACCOUNT'),
url => \&selectAccount,
}],
image => IMG_ACCOUNT,
};
}
# unshift @$items, {
# name => cstring($client, 'PLUGIN_SPOTTY_BROKEN'),
# type => 'textarea',
# };
$cb->({
# XXX - how to refresh the title when the account has changed?
# name => cstring($client, 'PLUGIN_SPOTTY_NAME') . (Plugins::Spotty::AccountHelper->hasMultipleAccounts() ? sprintf(' (%s)', Plugins::Spotty::AccountHelper->getDisplayName($spotty->username)) : ''),
items => $items,
});
} );
return;
}
sub home {
my ($client, $cb, $params) = @_;
my $ignoreItems = $prefs->client($client)->get('ignoreHomeItems');
Plugins::Spotty::Plugin->getAPIHandler($client)->home(sub {
my ($homeItems) = @_;
my %taglines;
my $items = sortHomeItems([ grep {
$taglines{$_->{uri}} = $_->{description};
$_->{name} && $_->{id} && !$ignoreItems->{$_->{id}};
} @$homeItems ]);
$cb->({ items => [ map {
$_->{line2} = $taglines{$_->{favorites_url}} if $taglines{$_->{favorites_url}};
$_;
} @{playlistList($client, $items)} ] });
});
}
sub sortHomeItems {
my $dailyMixRegex = qr/Daily Mix|MixTape/i;
my $weeklyMixRegex = qr/Discover Weekly|Mix der Woche/i;
my $releaseRadarRegex = qr/Release Radar/i;
return [ sort {
return -1 if $a->{name} =~ $dailyMixRegex && $b->{name} !~ $dailyMixRegex;
return 1 if $b->{name} =~ $dailyMixRegex && $a->{name} !~ $dailyMixRegex;
return -1 if $a->{name} =~ $releaseRadarRegex;
return 1 if $b->{name} =~ $releaseRadarRegex;
return -1 if $a->{name} =~ $weeklyMixRegex;
return 1 if $b->{name} =~ $weeklyMixRegex;
} @{$_[0]} ];
}
sub browseWebUrl {
my ($client, $cb, $params, $args) = @_;
if ($args && $args->{href}) {
Plugins::Spotty::Plugin->getAPIHandler($client)->browseWebUrl(sub {
my $results = shift;
my $items = [ grep { $_ } map {
my $type = $_->{type} || '';
my $innerItem;
if ($type eq 'album') {
$innerItem = _albumItem($client, $_);
}
elsif ($type eq 'artist') {
$innerItem = _artistItem($client, $_);
}
elsif ($type eq 'playlist') {
$innerItem = _playlistItem($client, $_);
if ($_->{description}) {
$innerItem->{name2} = $_->{description};
$innerItem->{name} .= ' - ' . $_->{description} if $params->{isWeb};
}
}
elsif ($type eq 'show') {
$innerItem = _showItem($_);
}
elsif ($_->{uri} eq 'spotify:collection:tracks') {
# "favorite tracks"? /me/tracks
}
else {
$log->warn("Unexpected content type found in home menu structure: $type " . (main::INFOLOG ? Data::Dump::dump($_) : ''));
}
$innerItem;
} @$results ];
$cb->({ items => $items });
}, $args->{href});
}
else {
$cb->([{
type => 'text',
title => cstring($client, 'EMPTY'),
}]);
}
}
sub search {
my ($client, $cb, $params, $args) = @_;
$params->{search} ||= $args->{query};
$params->{type} ||= $args->{type};
my $type = $params->{type} || '';
$type = '' if $type eq 'context';
if (my $uriInfo = parseUri($params->{search})) {
$args->{uri} = $uriInfo->{uri};
if ($uriInfo->{type} eq 'playlist') {
return playlist($client, $cb, $params, $args);
}
elsif ($uriInfo->{type} eq 'album') {
return album($client, $cb, $params, $args);
}
elsif ($uriInfo->{type} eq 'artist') {
return artist($client, $cb, $params, $args);
}
elsif ($uriInfo->{type} eq 'show') {
return show($client, $cb, $params, $args);
}
elsif ($uriInfo->{type} =~ /^(track|episode)$/) {
return Plugins::Spotty::Plugin->getAPIHandler($client)->trackCached(sub {
$cb->({ items => trackList($client, [shift]) });
}, $args->{uri});
}
}
my $spotty = Plugins::Spotty::Plugin->getAPIHandler($client);
# search for users is different...
if ($type eq 'user') {
$spotty->user(sub {
my ($result) = @_;
my $items = [];
if ($result && $result->{id}) {
my $title = $result->{id};
push @$items, {
type => 'text',
name => $result->{display_name} ? ($result->{display_name} . " ($title)") : $title,
image => $result->{image} || IMG_ACCOUNT,
},{
type => 'link',
name => cstring($client, 'PLAYLISTS'),
image => IMG_PLAYLIST,
url => \&playlists,
passthrough => [{
user => $result->{id}
}],
};
}
$cb->({ items => $items });
}, $params->{search});
return;
}
$spotty->search(sub {
my ($results) = @_;
my @items;
if ( !$type ) {
push @items, grep {
$_->{passthrough}->[0]->{type} ne 'track'
} @{
_searchItems($client, $params->{search})
};
push @items, @{trackList($client, $results)};
addRecentSearch($params->{search}) unless $args->{recent} || $params->{type} eq 'context';
splice(@items, $params->{quantity}) if defined $params->{index} && !$params->{index} && $params->{quantity} < scalar @items;
}
elsif ($type eq 'album') {
push @items, @{albumList($client, $results, 1)};
}
elsif ($type eq 'artist') {
push @items, @{artistList($client, $results)};
}
elsif ($type eq 'track') {
push @items, @{trackList($client, $results)};
}
elsif ($type eq 'playlist') {
push @items, @{playlistList($client, $results)};
}
elsif ($type eq 'show_audio') {
push @items, @{podcastList($client, $results)};
}
elsif ($type eq 'episode_audio') {
push @items, @{episodesList($client, $results)};
}
else {
$log->error("Unkonwn search type: ") . Data::Dump::dump($results);
}
$cb->({ items => \@items });
}, {
query => $params->{search},
type => $type || 'track',
limit => 50,
});
}
sub parseUri {
my ($uri) = @_;
my ($type, $id);
# https://open.spotify.com/playlist/3i6JdDL2IaDoIdrZCVngUv
if ($uri =~ m|open.spotify.com/(.+)/([a-z0-9]+)|i) {
$type = $1;
$id = $2;
$uri = "spotify:$type:$id";
}
elsif ($uri =~ /^spotify:(.+?):([a-z0-9]+)$/i) {
$type = $1;
$id = $2;
}
main::INFOLOG && $log->is_info && $log->info("URI info: " . Data::Dump::dump({
type => $type,
id => $id,
uri => $uri
}));
return $type && $id && {
type => $type,
id => $id,
uri => $uri
};
}
sub _searchItems {
my ($client, $query) = @_;
my @items = map {
{
name => cstring($client, $_->[0]),
image => $_->[2],
url => \&search,
passthrough => [{
query => $query,
type => $_->[1]
}]
}
} grep {
Plugins::Spotty::Helper->getCapability('podcasts') || $_->[1] !~ /^(?:show|episode)_/;
} (
[ 'ARTISTS', 'artist', IMG_ARTIST ],
[ 'ALBUMS', 'album', IMG_ALBUM ],
[ 'PLAYLISTS', 'playlist', IMG_PLAYLIST ],
[ 'SONGS', 'track', IMG_SONG ],
# https://github.com/spotify/web-api/issues/551#issuecomment-486898766
[ 'PLUGIN_SPOTTY_SHOWS', 'show_audio', IMG_PODCAST ],
[ 'PLUGIN_SPOTTY_EPISODES', 'episode_audio', IMG_PODCAST ],
[ 'PLUGIN_SPOTTY_USERS', 'user', IMG_ACCOUNT ]
);
return \@items
}
sub whatsNew {
my ($client, $cb, $params) = @_;
Plugins::Spotty::Plugin->getAPIHandler($client)->newReleases(sub {
my ($albums) = @_;
my $items = albumList($client, $albums, 1);
$cb->({ items => $items });
});
}
sub topTracks {
my ($client, $cb, $params) = @_;
Plugins::Spotty::Plugin->getAPIHandler($client)->topTracks(sub {
my ($tracks) = @_;
my $items = tracksList($client, $tracks);
$cb->({ items => $items });
});
}
sub categories {
my ($client, $cb, $params) = @_;
Plugins::Spotty::Plugin->getAPIHandler($client)->categories(sub {
my ($result) = @_;
my $items = [];
for my $item ( @{$result} ) {
push @{$items}, {
type => 'link',
name => $item->{name},
url => \&category,
passthrough => [{
id => $item->{id},
title => $item->{name},
}],
image => $item->{image},
};
}
$cb->({ items => $items })
});
}
sub mySongs {
my ($client, $cb, $params, $args) = @_;
Plugins::Spotty::Plugin->getAPIHandler($client)->mySongs(sub {
my ($result) = @_;
my ($items, $indexList) = trackList($client, $result);
push @$items, {
name => cstring($client, 'PLUGIN_SPOTTY_ADD_SONGS'),
type => 'text',
} unless scalar @$items;
$cb->({
items => $items,
indexList => $indexList
});
});
}
sub myAlbums {
my ($client, $cb, $params, $args) = @_;
Plugins::Spotty::Plugin->getAPIHandler($client)->myAlbums(sub {
my ($result) = @_;
my ($items, $indexList) = albumList($client, $result, !$prefs->get('sortAlbumsAlphabetically'));
push @$items, {
name => cstring($client, 'PLUGIN_SPOTTY_ADD_STUFF'),
type => 'text',
} unless scalar @$items;
$cb->({
items => $items,
indexList => $indexList
});
});
}
sub myArtists {
my ($client, $cb, $params) = @_;
Plugins::Spotty::Plugin->getAPIHandler($client)->myArtists(sub {
my ($result) = @_;
my ($items, $indexList) = artistList($client, $result, $prefs->get('myAlbumsOnly'), !$prefs->get('sortArtistsAlphabetically'));
push @$items, {
name => cstring($client, 'PLUGIN_SPOTTY_ADD_STUFF'),
type => 'text',
} unless scalar @$items;
$cb->({
items => $items,
indexList => $indexList
});
});
}
sub shows {
my ($client, $cb, $params) = @_;
Plugins::Spotty::Plugin->getAPIHandler($client)->myShows(sub {
my ($result) = @_;
my ($items, $indexList) = podcastList($client, $result);
$cb->({
items => $items,
indexList => $indexList
});
});
}
sub show {
my ($client, $cb, $params, $args) = @_;
Plugins::Spotty::Plugin->getAPIHandler($client)->episodes(sub {
my ($episodes) = @_;
if ($prefs->client($client)->get('reversePodcastOrder')) {
$episodes = [ reverse @$episodes ];
}
my $items = episodesList($client, $episodes);
push @$items, {
name => cstring($client, 'PLUGIN_SPOTTY_ADD_SHOW_TO_LIBRARY'),
url => \&addShowToLibrary,
passthrough => [{ id => $args->{id}, name => $args->{name} }],
nextWindow => 'parent'
};
if ($args->{description}) {
push @$items, {
name => cstring($client, 'DESCRIPTION'),
items => [{
name => $args->{description},
type => 'textarea'
}]
};
}
if ($args->{languages}) {
my $lang = ref $args->{languages} ? join(', ', map { uc } @{$args->{languages}}) : uc($args->{languages});
push @$items, {
name => cstring($client, 'LANGUAGE') . cstring($client, 'COLON') . " $lang",
type => 'text'
} if $lang;
}
$cb->({ items => $items });
}, {
id => $args->{id}
});
}
sub addShowToLibrary {
my ($client, $cb, $params, $args) = @_;
$args ||= {};
Plugins::Spotty::Plugin->getAPIHandler($client)->addShowToLibrary(sub {
$cb->({ items => [{
name => cstring($client, 'PLUGIN_SPOTTY_MUSIC_ADDED'),
showBriefly => 1
}] });
}, $params->{ids} || $args->{ids} || $params->{id} || $args->{id});
}
sub playlists {
my ($client, $cb, $params, $args) = @_;
my $spotty = Plugins::Spotty::Plugin->getAPIHandler($client);
$spotty->playlists(sub {
my ($result) = @_;
my $items;
Plugins::Spotty::PlaylistFolders->getTree($spotty, [ map {
$_->{uri};
} @$result ], sub {
my $hierarchy = shift;
if ($hierarchy) {
main::INFOLOG && $log->is_info && $log->info("Found playlist folder hierarchy! Let's use it: " . Data::Dump::dump($hierarchy));
$items = Plugins::Spotty::PlaylistFolders->render($result, $hierarchy, sub {
playlistList($client, [shift]);
});
}
else {
$items = playlistList($client, $result);
push @$items, {
name => cstring($client, 'PLUGIN_SPOTTY_ADD_STUFF'),
type => 'text',
} unless scalar @$items;
}
$cb->({ items => $items });
});
},{
user => $params->{user} || $args->{user}
});
}
sub album {
my ($client, $cb, $params, $args) = @_;
Plugins::Spotty::Plugin->getAPIHandler($client)->album(sub {
my ($album) = @_;
my $items = trackList($client, $album->{tracks}, { show_numbers => 1 });
push @$items, {
name => cstring($client, 'PLUGIN_SPOTTY_ADD_ALBUM_TO_LIBRARY'),
url => \&addAlbumToLibrary,
passthrough => [{ id => $album->{id}, name => $album->{name} }],
nextWindow => 'parent'
};
my %artists;
for my $track ( @{ $album->{tracks} } ) {
for my $artist ( @{ $track->{artists} } ) {
next unless $artist->{uri};
$artists{ $artist->{name} } = $artist->{uri};
}
}
my $prefix = cstring($client, 'ARTIST') . cstring($client, 'COLON') . ' ';
for my $artist ( sort keys %artists ) {
push @$items, {
name => $prefix . $artist,
url => \&artist,
passthrough => [{ uri => $artists{$artist} }],
image => IMG_ARTIST,
};
}
if ( $album->{release_date} && $album->{release_date} =~ /\b(\d{4})\b/ ) {
push @{$items}, {
name => cstring($client, 'YEAR') . cstring($client, 'COLON') . " $1",
type => 'text',
};
}
$cb->({ items => $items });
},{
uri => $params->{uri} || $args->{uri} || $params->{extid} || $args->{extid}
});
}
sub addAlbumToLibrary {
my ($client, $cb, $params, $args) = @_;
$args ||= {};
Plugins::Spotty::Plugin->getAPIHandler($client)->addAlbumToLibrary(sub {
$cb->({ items => [{
name => cstring($client, 'PLUGIN_SPOTTY_MUSIC_ADDED'),
showBriefly => 1
}] });
}, $params->{ids} || $args->{ids} || $params->{id} || $args->{id});
}
sub artist {
my ($client, $cb, $params, $args) = @_;
my $uri = $params->{uri} || $args->{uri};
my $spotty = Plugins::Spotty::Plugin->getAPIHandler($client);
# get artist, tracks and albums asynchronously, only process once we have it all
$client->pluginData(artistInfo => {});
$spotty->artist(sub {
_gotArtistData($client, $cb, artist => $_[0]);
},{
uri => $uri
}, );
$spotty->artistTracks(sub {
_gotArtistData($client, $cb, tracks => $_[0]);
}, {
uri => $uri
});
$spotty->artistAlbums(sub {
my $albums = shift;
# Sort albums by release date
$albums = [ sort { $b->{released} <=> $a->{released} } @$albums ];
# some users only want to see the albums they have added to their library when browsing library artists
if ( $args->{myAlbumsOnly} ) {
$spotty->isInMyAlbums(sub {
my $inMyAlbums = shift || {};
_gotArtistData($client, $cb, albums => [ grep { $inMyAlbums->{$_->{id}} } @$albums ]);
}, [ map { $_->{id} } @$albums ]);
}
else {
_gotArtistData($client, $cb, albums => $albums);
}
}, {
uri => $uri
});
}
sub _gotArtistData {
my ($client, $cb, $type, $data) = @_;
my $artistInfo = $client->pluginData('artistInfo') || {};
$artistInfo->{$type} = $data;
$client->pluginData(artistInfo => $artistInfo);
return unless $artistInfo->{tracks} && $artistInfo->{albums} && $artistInfo->{artist};
my $artist = $artistInfo->{artist} || {};
my $artistURI = $artist->{uri};
my $items = [];
# Split albums into compilations (albums with a different primary artist name), singles, and regular albums
# XXX Need a better way to determine album type. Unfortunately album->{album_type} doesn't work
my $albums = albumList($client, [ grep { $_->{album_type} ne 'single' && $_->{artist} eq $artist->{name} } @{ $artistInfo->{albums} } ]);
my $singles = albumList($client, [ grep { $_->{album_type} eq 'single' } @{ $artistInfo->{albums} } ]);
my $comps = albumList($client, [ grep { $_->{album_type} ne 'single' && $_->{artist} ne $artist->{name} } @{ $artistInfo->{albums} } ]);
if ( scalar @$albums ) {
push @$items, {
name => cstring($client, 'ALBUMS'),
icon => IMG_ALBUM,
items => $albums,
};
}
if ( scalar @$singles ) {
push @$items, {
name => cstring($client, 'PLUGIN_SPOTTY_SINGLES'),
icon => IMG_SONG,
items => $singles,
};
}
if ( scalar @$comps ) {
push @$items, {
name => cstring($client, 'PLUGIN_SPOTTY_COMPILATIONS'),
icon => IMG_COMPILATION,
items => $comps,
};
}
push @$items, {
type => 'outline',
name => cstring($client, 'PLUGIN_SPOTTY_TOP_TRACKS'),
icon => IMG_TOPTRACKS,
items => trackList($client, $artistInfo->{tracks}),
# },{
# type => 'playlist',
# name => cstring($client, 'SONGS'),
# url => \&search,
# passthrough => [{
# query => 'artist:"' . $artist->{name} . '"',
# type => 'track'
# }]
} if @{$artistInfo->{tracks}};
push @$items, {
type => 'playlist',
on_select => 'play',
name => cstring($client, 'PLUGIN_SPOTTY_ARTIST_RADIO'),
icon => IMG_RADIO,
url => \&artistRadio,
passthrough => [{ uri => $artistURI }],
},{
name => cstring($client, 'PLUGIN_SPOTTY_RELATED_ARTISTS'),
icon => IMG_ARTIST,
url => \&relatedArtists,
passthrough => [{ uri => $artistURI }],
},{
name => cstring($client, 'PLUGIN_SPOTTY_FOLLOW_ARTIST'),
icon => IMG_FOLLOW_ARTIST,
url => \&followArtist,