-
Notifications
You must be signed in to change notification settings - Fork 0
/
nucrat.f
1146 lines (880 loc) · 48 KB
/
nucrat.f
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC
C Changes (to run inder DEC unix f77):
C -----------------------------------
C COMMON /therm/ -> COMMON /thermcb/
C COMMON /rates/ f,r(nrec) -> COMMON /rates/ f,r
C
C Default neutron lifetime 888.54 -> 885.7 (+- 0.8) - PDG 2002/3
SUBROUTINE rate0
C----------LINKAGES.
C CALLED BY - [subroutine] start
C CALLS - none
C----------REMARKS.
C Generates weak decay rates.
C----------PARAMETER.
PARAMETER (nrec=123) !Number of nuclear reactions. (Ninja)
C----------COMMON AREA.
COMMON /rates/ f,r !Reaction rates.
C==========================DECLARATION DIVISION=================================
C----------REACTION RATE COEFFICIENTS.
REAL f(nrec) !Forward reaction rate coefficients.
REAL r(nrec)
C===========================PROCEDURE DIVISION==================================
C10--------SET DECAY RATE COEFFICIENTS------------------------------------------
C.......H3 -> e- + v + He3.........(Tilly-Weller-Hasan 1987)
f(2) = 1.79e-9
C.......Li8 -> e- + v + 2He4.......(Ajzenberg-Selove 1988)
f(3) = 8.27e-1
C.......B12 -> e- + B + C12........(Ajzenberg-Selove 1990)
f(4) = 3.43e+1
C.......C14 -> e- + v + N14........(Ajzenberg-Selove 1986)
f(5) = 3.834e-12
C.......B8 -> e+ + v + 2He4........(Ajzenberg-Selove 1988)
f(6) = 9.00e-1
C.......C11 -> e+ + v + B11........(Ajzenberg-Selove 1990)
f(7) = 5.668e-4
C.......N12 -> e+ + v + C12........(Ajzenberg-Selove 1990)
f(8) = 6.301e+1
C.......N13 -> e+ + v + C13........(Ajzenberg-Selove 1986)
f(9) = 1.159e-3
C.......O14 -> e+ + v + N14........(Ajzenberg-Selove 1986)
f(10) = 9.8171e-3
C.......O15 -> e+ + v + N15........(Ajzenberg-Selove 1986)
f(11) = 5.6704e-3
RETURN
C----------REFERENCES-----------------------------------------------------------
C Ajzenberg-Selove, F., 1990, Nucl. Phys. A506, 1.
C Ajzenberg-Selove, F., 1988, Nucl. Phys. A490, 1.
C Ajzenberg-Selove, F., 1986, Nucl. Phys. A449, 1.
C Tilley, D.R., Weller, H.R., and Hasan, H.H., 1987, Nucl. Phys. A474, 1.
END
C========================IDENTIFICATION DIVISION================================
SUBROUTINE rate1(tph)
C----------LINKAGES.
C CALLED BY - [subroutine] start, derivs
C CALLS - [function] xintd, eval
C----------REMARKS.
C Generates rate coefficients for weak n->p and p->n reactions.
C----------PARAMETERS.
PARAMETER (nrec=123) !Number of nuclear reactions. (Ninja)
PARAMETER (iter=50) !Number of gaussian quads.
C----------COMMON AREAS.
COMMON /rates/ f,r !Reaction rates.
COMMON /modpr/ g,tau,xnu,c(3),cosmo,xi !Model parameters.
COMMON /thermcb/ thm,hubcst !Dynamic variables.
COMMON /nupar/ t9mev,tnmev,tnu,cnorm,nu,rhonu !Integration parameters.
C----------EXTERNAL FUNCTIONS.
EXTERNAL func1 !Part 1 of n->p rate.
EXTERNAL func2 !Part 2 of n->p rate.
EXTERNAL func3 !Part 1 of p->n rate.
EXTERNAL func4 !Part 2 of p->n rate.
C==========================DECLARATION DIVISION=================================
C----------REACTION RATES.
REAL f(nrec) !Forward reaction rate coefficients.
REAL r(nrec) !Reverse reaction rate coefficients.
C----------EARLY UNIVERSE MODEL PARAMETERS.
REAL tau !Neutron lifetime.
REAL xi(3) !Neutrino degeneracy parameters.
| !xi(1) is e neutrino degeneracy parameter.
| !xi(2) is m neutrino degeneracy parameter.
| !xi(3) is t neutrino degeneracy parameter.
C----------DYNAMIC VARIABLES.
REAL thm(14) !Thermodynamic variables (energy densities).
C----------NEUTRINO PARAMETERS.
REAL t9mev !Temperature (in units of MeV).
REAL tnmev !Neutrino temperature (in units of MeV).
C----------LOCAL VARIABLES.
REAL tph !Photon temperature.
REAL w(2),x(2), !Upper limits for exponentials, forward rate.
| y(2),z(2) !Upper limits for exponentials, reverse rate.
REAL uplim1,uplim2, !Upper limits for integrals for forward rate.
| uplim3,uplim4 !Upper limits for integrals for reverse rate.
REAL part1,part2, !Parts of integrals for forward rate.
| part3,part4 !Parts of integrals for reverse rate.
C===========================PROCEDURE DIVISION==================================
C10--------COMPUTE WEAK REACTION RATES (NONDEGENERATE)--------------------------
IF (xi(1).eq.0.) THEN
f(1) = thm(13)/tau !Forward rate for weak np reaction.
r(1) = thm(14)/tau !Reverse rate for weak np reaction.
ELSE
C20--------COMPUTE WEAK REACTION RATES (DEGENERATE)-----------------------------
t9mev = tph*.086171 !Convert photon temp to units of MeV.
tnmev = tnu*.086171 !Convert neutrino temp to units of MeV.
C..........COMPUTE OVERFLOW LIMITS FOR LIMITS OF INTEGRATION (Ref 1 & 2).
w(1) = (-(t9mev/.511)*(-88.722))
w(2) = ((tnmev/.511)*(88.029+xi(1))+2.531)
x(1) = ((t9mev/.511)*(88.029))
x(2) = (-(tnmev/.511)*(-88.722+xi(1))-2.531)
y(1) = (-(t9mev/.511)*(-88.722))
y(2) = ((tnmev/.511)*(88.029-xi(1))-2.531)
z(1) = ((t9mev/.511)*(88.029))
z(2) = (-(tnmev/.511)*(-88.722-xi(1))+2.531)
C..........COMPARE LIMITS AND TAKE LARGER OF THE TWO.
uplim1 = abs(w(1))
uplim2 = abs(x(1))
uplim3 = abs(y(1))
uplim4 = abs(z(1))
IF (uplim1.lt.abs(w(2))) uplim1 = w(2)
IF (uplim2.lt.abs(x(2))) uplim2 = x(2)
IF (uplim3.lt.abs(y(2))) uplim3 = y(2)
IF (uplim4.lt.abs(z(2))) uplim4 = z(2)
C..........EVALUATE THE INTEGRALS NUMERICALLY.
part1 = xintd(1.,uplim1,func1,iter)
part2 = xintd(1.,uplim2,func2,iter)
part3 = xintd(1.,uplim3,func3,iter)
part4 = xintd(1.,uplim4,func4,iter)
f(1) = part1 + part2 !Add 2 integrals to get forward rate.
r(1) = part3 + part4 !Add 2 integrals to get reverse rate.
END IF !(xi(1).eq.0.)
RETURN
C----------REFERENCES-----------------------------------------------------------
C 1) Forms of the integrals involved can be found in
C Scherrer,R.J., 1983, Mon.Not.R.astr.Soc., 205, 683.
C Beaudet,G. and Goret,P., 1976, Astron. & Astrophys., 49, 415.
C
C 2) The overflow limit for the VAX/VMS system is exp(88.029).
C The underflow limit for the VAX/VMS system is exp(-88.722).
END
C========================IDENTIFICATION DIVISION================================
SUBROUTINE rate2
C----------LINKAGES.
C CALLED BY - [subroutine] derivs
C CALLS - [function] ex
C----------REMARKS.
C Generates rate coefficients for reactions involving nuclides
C up to A = 9.
C----------PARAMETER.
PARAMETER (nrec=123) !Number of nuclear reactions. (Ninja)
PARAMETER (nnuc=30) !Number of nuclides in calculation. (Ninja)
C----------COMMON AREAS.
COMMON /rates/ f,r !Reaction rates.
COMMON /evolp1/ t9,hv,phie,y(nnuc) !Evolution parameters.
C==========================DECLARATION DIVISION=================================
C----------REACTION RATES.
REAL f(nrec) !Forward reaction rate coefficients.
real r(nrec)
C----------EVOLUTION PARAMETER.
REAL t9 !Temperature of photons (units of 10**9 K).
C===========================PROCEDURE DIVISION==================================
C10--------TEMPERATURE FACTORS--------------------------------------------------
t913 = t9**(.33333333) !t9**(1/3)
t923 = t913*t913 !t9**(2/3)
t943 = t923*t923 !t9**(4/3)
t953 = t9*t923 !t9**(5/3)
t912 = sqrt(t9) !t9**(1/2)
t932 = t9*t912 !t9**(3/2)
t9m1 = 1/t9 !t9**(-1)
t9m23 = 1.0/t923 !t9**(-2/3)
t9m32 = 1.0/t932 !t9**(-3/2)
t9a = t9/(1.0+13.076*t9) !For reaction 17.
t9a32 = t9a**(1.5) !t9a**(3/2)
t9b = t9/(1.+49.18*t9) !For reaction 18.
t9b32 = t9b**(1.5) !t9b**(3/2)
IF (t9.gt.10.) THEN !For reaction 22.
t9c = 1.
ELSE
t9c = t9/(1.-9.69e-2*t9+2.84e-2*t953/(1.-9.69e-2*t9)**(2./3.))
END IF
t9c13 = t9c**(.3333333) !t9c**(1/3)
t9c56 = t9c**(.8333333) !t9c**(5/6)
t9d = t9/(1.+0.759*t9) !For reaction 24.
t9d13 = t9d**(.3333333) !t9d**(1/3)
t9d56 = t9d**(.8333333) !t9d**(5/6)
t9e = t9/(1.+0.1378*t9) !For reaction 26.
t9e13 = t9e**(.3333333) !t9e**(1/3)
t9e56 = t9e**(.8333333) !t9e**(5/6)
t9f = t9/(1.+0.1071*t9) !For reaction 27.
t9f13 = t9f**(.3333333) !t9f**(1/3)
t9f56 = t9f**(.8333333) !t9f**(5/6)
C20--------NEUTRON, PHOTON REACTIONS--------------------------------------------
C.......H(n,g)H2...................(Smith-Kawano-Malaney 1992)
f(12) = 4.742e+4*(1.-.8504*t912+.4895*t9-.09623*t932
| +8.471e-3*t9*t9-2.80e-4*t9*t932)
C.......H2(n,g)H3..................(Wagoner 1969)
f(13) = 6.62e+1*(1.+18.9*t9)
C.......He3(n,g)He4................(Wagoner 1969)
f(14) = 6.62e+0*(1.+905.*t9)
C.......Li6(n,g)Li7................(Malaney-Fowler 1989)
f(15) = 5.10e+3
C30--------NEUTRON, PROTON REACTIONS--------------------------------------------
C.......He3(n,p)H3.................(Smith-Kawano-Malaney 1992)
f(16) = 7.21e+8*(1.-.508*t912+.228*t9)
C.......Be7(n,p)Li7................(Smith-Kawano-Malaney 1992)
f(17) = 2.675e+9*(1.-.560*t912+.179*t9-.0283*t932
| + 2.214e-3*t9*t9-6.851e-5*t9*t932)
| + 9.391e+8*t9a32*t9m32
| + 4.467e+7*t9m32*ex(-0.07486/t9)
C40--------NEUTRON, ALPHA REACTIONS---------------------------------------------
C.......Li6(n,a)H3.................(Caughlan-Fowler 1988)
f(18) = 2.54e+9*t9m32*ex(-2.39/t9)
| + 1.68e+8*(1.-.261*t9b32/t932)
C.......Be7(n,a)He4................(Wagoner 1969)
f(19) = 2.05e+4*(1.+3760.*t9)
C50--------PROTON, PHOTON REACTIONS---------------------------------------------
C.......H2(p,g)He3.................(Smith-Kawano-Malaney 1992)
f(20) = 2.65e+3*t9m23*ex(-3.720/t913)
| *(1.+.112*t913+1.99*t923+1.56*t9+.162*t943+.324*t953)
C.......H3(p,g)He4.................(Caughlan-Fowler 1988)
f(21) = 2.20e+4*t9m23*ex(-3.869/t913)
| *(1.+.108*t913+1.68*t923+1.26*t9+.551*t943+1.06*t953)
C.......Li6(p,g)Be7................(Caughlan-Fowler 1988)
f(22) = 6.69e+5*t9c56*t9m32*ex(-8.413/t9c13)
C60--------PROTON, ALPHA REACTIONS----------------------------------------------
C.......Li6(p,a)He3................(Caughlan-Fowler 1988)
f(23) = 3.73e+10*t9m23*ex(-8.413/t913-(t9/5.50)**2)
| *(1.+.050*t913-.061*t923-.021*t9+.006*t943+.005*t953)
| + 1.33e+10*t9m32*ex(-17.763/t9)
| + 1.29e+09*t9m1*ex(-21.820/t9)
C.......Li7(p,a)He4................(Smith-Kawano-Malaney 1992)
f(24) = 1.096e+9*t9m23*ex(-8.472/t913)
| - 4.830e+8*t9d56*t9m32*ex(-8.472/t9d13)
| + 1.06e+10*t9m32*ex(-30.442/t9)
| + 1.56e+5*t9m23*ex((-8.472/t913)-(t9/1.696)**2)
| *(1.+.049*t913-2.498*t923+.860*t9+3.518*t943+3.08*t953)
| + 1.55e+6*t9m32*ex(-4.478/t9)
C70--------ALPHA, PHOTON REACTIONS----------------------------------------------
C.......H2(a,g)Li6.................(Caughlan-Fowler 1988)
f(25) = 3.01e+01*t9m23*ex(-7.423/t913)
| *(1.+.056*t913-4.85*t923+8.85*t9-.585*t943-.584*t953)
| + 8.55e+1*t9m32*ex(-8.228/t9)
C.......H3(a,g)Li7.................(Smith-Kawano-Malaney 1992)
f(26) = 3.032e+5*t9m23*ex(-8.090/t913)
| *(1.+.0516*t913+.0229*t923+8.28e-3*t9
| -3.28e-4*t943-3.01e-4*t953)
| + 5.109e+5*t9e56*t9m32*ex(-8.068/t9e13)
C.......He3(a,g)Be7................(Smith-Kawano-Malaney 1992)
f(27) = 4.817e+6*t9m23*ex(-14.964/t913)
| *(1.+.0325*t913-1.04e-3*t923-2.37e-4*t9
| -8.11e-5*t943-4.69e-5*t953)
| + 5.938e+6*t9f56*t9m32*ex(-12.859/t9f13)
C80--------DEUTERIUM, NEUTRON AND DEUTERIUM, PROTON REACTIONS-------------------
C.......H2(d,n)He3.................(Smith-Kawano-Malaney 1992)
f(28) = 3.95e+8*t9m23*ex(-4.259/t913)
| *(1.+.098*t913+.765*t923+.525*t9+9.61e-3*t943+.0167*t953)
C.......H2(d,p)H3..................(Smith-Kawano-Malaney 1992)
f(29) = 4.17e+8*t9m23*ex(-4.258/t913)
| *(1.+.098*t913+.518*t923+.355*t9-.010*t943-.018*t953)
! f(29) = 2.24e-9*((t9/300)**(0.042))*ex(-t9/46600)
C.......H3(d,n)He4.................(Smith-Kawano-Malaney 1992)
f(30) = 1.063e+11*t9m23*ex(-4.559/t913-(t9/.0754)**2)
| *(1.+.092*t913-.375*t923-.242*t9+33.82*t943+55.42*t953)
| + 8.047e+8*t9m23*ex(-0.4857/t9)
C.......He3(d,p)He4................(Smith-Kawano-Malaney 1992)
f(31) = 5.021e+10*t9m23*ex(-7.144/t913-(t9/.270)**2)
| *(1.+.058*t913+.603*t923+.245*t9+6.97*t943+7.19*t953)
| + 5.212e+8/t912*ex(-1.762/t9)
C90--------THREE PARTICLE REACTIONS---------------------------------------------
C.......He3(He3,2p)He4.............(Caughlan-Fowler 1988)
f(32) = 6.04e+10*t9m23*ex(-12.276/t913)
| *(1.+.034*t913-.522*t923-.124*t9+.353*t943+.213*t953)
C.......Li7(d,na)He4...............(Caughlan-Fowler 1988)
f(33) = 2.92e+11*t9m23*ex(-10.259/t913)
C.......Be7(d,pa)He4...............(Caughlan-Fowler 1988)
f(34) = 1.07e+12*t9m23*ex(-12.428/t913)
RETURN
C----------REFERENCES-----------------------------------------------------------
C Smith, M., Kawano, L.H., and Malaney, R.A., 1992, submitted to Ap. J.
C Malaney, R.A., and Fowler, W.A., 1989, Astrophys. J., 345, L5.
C Caughlan, G.R., and Fowler, W.A., 1988, Atomic Data and Nuclear Data
C Tables, 40, 283.
C Wagoner, R.V.,1969, Ap. J. Suppl. No. 162, 18, 247.
END
C========================IDENTIFICATION DIVISION================================
SUBROUTINE rate3
C----------LINKAGES.
C CALLED BY - [subroutine] derivs
C CALLS - [function] ex
C----------REMARKS.
C Generates rate coefficients for reactions involving nuclides
C up to A = 18.
C----------PARAMETER.
PARAMETER (nrec=123) !Number of nuclear reactions. (Ninja)
PARAMETER (nnuc=30) !Number of nuclides in calculation. (Ninja)
C----------COMMON AREAS.
COMMON /rates/ f,r !Reaction rates.
COMMON /evolp1/ t9,hv,phie,y(nnuc) !Evolution parameters.
C==========================DECLARATION DIVISION=================================
C----------REACTION RATES.
REAL f(nrec) !Forward reaction rate coefficients.
real r(nrec)
C----------EVOLUTION PARAMETER.
REAL t9 !Temperature of photons (units of 10**9 K).
C===========================PROCEDURE DIVISION==================================
C10--------TEMPERATURE FACTORS--------------------------------------------------
t913 = t9**(.33333333) !t9**(1/3)
t923 = t913*t913 !t9**(2/3)
t943 = t923*t923 !t9**(4/3)
t953 = t9*t923 !t9**(5/3)
t912 = sqrt(t9) !t9**(1/2)
t932 = t9*t912 !t9**(3/2)
t915 = t9**(.2) !t9**(1/5)
t954 = t9**(1.25) !t9**(5/4)
t9m1 = 1.0/t9 !t9**(-1)
t9m23 = 1.0/t923 !t9**(-2/3)
t9m32 = 1.0/t932 !t9**(-3/2)
t9m34 = sqrt(t9m32) !t9**(-3/4)
t9m15 = 1.0/t915 !t9**(-1/5)
t9m54 = 1.0/t954 !t9**(-5/4)
t9a = t9/(1.+t9/15.1) !For reaction 53.
t9a13 = t9a**(.3333333) !t9a**(1/3)
t9a56 = t9a**(.8333333) !t9a**(5/6)
C20--------NEUTRON, PHOTON REACTIONS--------------------------------------------
C.......Li7(n,g)Li8................(Wagoner 1969)
f(35) = 4.90e+3 + 9.96e+3*t9m32*ex(-2.62/t9)
C.......B10(n,g)B11................(Wagoner 1969)
f(36) = 6.62e+4
C.......B11(n,g)B12................(Malaney-Fowler 1989)
f(37) = 7.29e+2 + 2.40e+3*t9m32*ex(-0.223/t9)
C30--------NEUTRON, PROTON REACTIONS--------------------------------------------
C.......C11(n,p)B11................(Caughlan-Fowler 1988)
f(38) = 1.69e+8*(1.-.048*t912+.010*t9)
C40--------NEUTRON, ALPHA REACTIONS---------------------------------------------
C.......B10(n,a)Li7................(Caughlan-Fowler 1988)
f(39) = 5.07e+8
C50--------PROTON, PHOTON REACTIONS---------------------------------------------
C.......Be7(p,g)B8.................(Caughlan-Fowler 1988)
f(40) = 3.11e+5*t9m23*ex(-10.262/t913)
| + 2.53e+3*t9m32*ex(-7.306/t9)
C.......Be9(p,g)B10................(Caughlan-Fowler 1988)
f(41) = 1.33e+7*t9m23*ex(-10.359/t913-(t9/.846)**2)
| *(1.+.040*t913+1.52*t923+.428*t9+2.15*t943+1.54*t953)
| + 9.64e+4*t9m32*ex(-3.445/t9)
| + 2.72e+6*t9m32*ex(-10.620/t9)
C.......B10(p,g)C11................(Caughlan-Fowler 1988)
f(42) = 4.61e+5*t9m23*ex(-12.062/t913-(t9/4.402)**2)
| *(1.+.035*t913+.426*t923+.103*t9+.281*t943+.173*t953)
| + 1.93e+5*t9m32*ex(-12.041/t9)
| + 1.14e+4*t9m32*ex(-16.164/t9)
C.......B11(p,g)C12................(Caughlan-Fowler 1988)
f(43) = 4.62e+7*t9m23*ex(-12.095/t913-(t9/.239)**2)
| *(1.+.035*t913+3.00*t923+.723*t9+9.91*t943+6.07*t953)
| + 7.89e+3*t9m32*ex(-1.733/t9)
| + 9.68e+4*t9m15*ex(-5.617/t9)
C.......C11(p,g)N12................(Caughlan-Fowler 1988)
f(44) = 4.24e+4*t9m23*ex(-13.658/t913-(t9/1.627)**2)
| *(1.+.031*t913+3.11*t923+.665*t9+4.61*t943+2.50*t953)
| + 8.84e+3*t9m32*ex(-7.021/t9)
C60--------PROTON, NEUTRON REACTIONS--------------------------------------------
C.......B12(p,n)C12................(Wagoner 1969)
f(45) = 4.02e+11*t9m23*ex(-12.12/t913)
C70--------PROTON, ALPHA REACTIONS----------------------------------------------
C.......Be9(p,a)Li6................(Caughlan-Fowler 1988)
f(46) = 2.11e+11*t9m23*ex(-10.359/t913-(t9/.520)**2)
| *(1.+.040*t913+1.09*t923+.307*t9+3.21*t943+2.30*t953)
| + 4.51e+8*t9m1*ex(-3.046/t9)
| + 6.70e+8*t9m34*ex(-5.160/t9)
C.......B10(p,a)Be7................(Caughlan-Fowler 1988)
f(47) = 1.26e+11*t9m23*ex(-12.062/t913-(t9/4.402)**2)
| *(1.+.035*t913-.498*t923-.121*t9+.300*t943+.184*t953)
| + 2.59e+9*t9m1*ex(-12.260/t9)
C.......B12(p,a)Be9................(Wagoner 1969)
f(48) = 2.01e+11*t9m23*ex(-12.12/t913)
C80--------ALPHA, PHOTON REACTIONS----------------------------------------------
C.......Li6(a,g)B10................(Caughlan-Fowler 1988)
f(49) = 4.06e+6*t9m23*ex(-18.790/t913-(t9/1.326)**2)
| *(1.+.022*t913+1.54*t923+.239*t9+2.20*t943+.869*t953)
| + 1.91e+3*t9m32*ex(-3.484/t9)
| + 1.01e+4*t9m1*ex(-7.269/t9)
C.......Li7(a,g)B11................(Caughlan-Fowler 1988)
f(50) = 3.55e+7*t9m23*ex(-19.161/t913-(t9/4.195)**2)
| *(1.+.022*t913+.775*t923+.118*t9+.884*t943+.342*t953)
| + 3.33e+2*t9m32*ex(-2.977/t9)
| + 4.10e+4*t9m1*ex(-6.227/t9)
C.......Be7(a,g)C11................(Caughlan-Fowler 1988)
f(51) = 8.45e+7*t9m23*ex(-23.212/t913-(t9/4.769)**2)
| *(1.+.018*t913+.488*t923+.061*t9+.296*t943+.095*t953)
| + 1.25e+4*t9m32*ex(-6.510/t9)
| + 1.29e+5*t9m54*ex(-10.039/t9)
C90--------ALPHA, PROTON REACTIONS----------------------------------------------
C.......B8(a,p)C11.................(Wagoner 1969)
f(52) = 1.08e+15*t9m23*ex(-27.36/t913)
C100-------ALPHA, NEUTRON REACTIONS---------------------------------------------
C.......Li8(a,n)B11................(Malaney-Fowler 1989)
f(53) = 8.62e+13*t9a56*t9m32*ex(-19.461/t9a13)
C.......Be9(a,n)C12................(Caughlan-Fowler 1988)
f(54) = 4.62e+13*t9m23*ex(-23.870/t913-(t9/.049)**2)
| *(1.+.017*t913+8.57*t923+1.05*t9+74.51*t943+23.15*t953)
| + 7.34e-5*t9m32*ex(-1.184/t9)
| + 2.27e-1*t9m32*ex(-1.834/t9)
| + 1.26e+5*t9m32*ex(-4.179/t9)
| + 2.40e+8*ex(-12.732/t9)
C110-------DEUTERIUM, NEUTRON AND DEUTERIUM, PROTON REACTIONS-------------------
C.......Be9(d,n)B10................(original Wagoner code)
f(55) = 7.16e+8*t9m23*ex(6.44-12.6/t913)
C.......B10(d,p)B11................(original Wagoner code)
f(56) = 9.53e+8*t9m23*ex(7.30-14.8/t913)
C.......B11(d,n)C12................(original Wagoner code)
f(57) = 1.41e+9*t9m23*ex(7.40-14.8/t913)
C120-------THREE PARTICLE REACTIONS---------------------------------------------
C.......He4(an,g)Be9...............(Caughlan-Fowler 1988)
f(58) = (2.59e-6/((1.+.344*t9)*t9**2))*ex(-1.062/t9)
C.......He4(2a,g)C12...............(Caughlan-Fowler 1988)
f(59) = 2.79e-8*t9m32*t9m32*ex(-4.4027/t9)
| + 1.35e-8*t9m32*ex(-24.811/t9)
C.......Li8(p,na)He4...............(original Wagoner code)
f(60) = 8.65e+9*t9m23*ex(-8.52/t913-(t9/2.53)**2)
| + 2.31e+9*t9m32*ex(-4.64/t9)
C.......B8(n,pa)He4................(original Wagoner code)
f(61) = 4.02e+8
C.......Be9(p,da)He4...............(Caughlan-Fowler 1988)
f(62) = 2.11e+11*t9m23*ex(-10.359/t913-(t9/.520)**2)
| *(1.+.040*t913+1.09*t923+.307*t9+3.21*t943+2.30*t953)
| + 5.79e+8*t9m1*ex(-3.046/t9)
| + 8.50e+8*t9m34*ex(-5.800/t9)
C.......B11(p,2a)He4...............(Caughlan-Fowler 1988)
f(63) = 2.20e+12*t9m23*ex(-12.095/t913-(t9/1.644)**2)
| *(1.+.034*t913+.140*t923+.034*t9+.190*t943+.116*t953)
| + 4.03e+6*t9m32*ex(-1.734/t9)
| + 6.73e+9*t9m32*ex(-6.262/t9)
| + 3.88e+9*t9m1*ex(-14.154/t9)
C.......C11(n,2a)He4...............(Wagoner 1969)
f(64) = 1.58e+8
RETURN
C----------REFERENCES-----------------------------------------------------------
C Malaney, R.A., and Fowler, W.A., 1989, Astrophys. J., 345, L5.
C Caughlan, G.R., and Fowler, W.A., 1988, Atomic Data and Nuclear Data
C Tables, 40, 283.
C Wagoner, R.V.,1969, Ap. J. Suppl. No. 162, 18, 247.
END
C========================IDENTIFICATION DIVISION================================
SUBROUTINE rate4
C----------LINKAGES.
C CALLED BY - [subroutine] derivs
C CALLS - [function] ex
C----------REMARKS.
C Generates rate coefficients for rest of reactions.
C----------PARAMETER.
PARAMETER (nrec=123) !Number of nuclear reactions.
PARAMETER (nnuc=30) !Number of nuclides in calculation.
C----------COMMON AREAS.
COMMON /rates/ f,r !Reaction rates.
COMMON /evolp1/ t9,hv,phie,y(nnuc) !Evolution parameters.
C==========================DECLARATION DIVISION=================================
C----------REACTION RATES.
REAL f(nrec) !Forward reaction rate coefficients.
real r(nrec)
C----------EVOLUTION PARAMETER.
REAL t9 !Temperature of photons (units of 10**9 K).
C===========================PROCEDURE DIVISION==================================
C10--------TEMPERATURE FACTORS--------------------------------------------------
t913 = t9**(.33333333) !t9**(1/3)
t923 = t913*t913 !t9**(2/3)
t943 = t923*t923 !t9**(4/3)
t953 = t9*t923 !t9**(5/3)
t912 = sqrt(t9) !t9**(1/2)
t932 = t9*t912 !t9**(3/2)
t935 = t9**(.6) !t9**(3/5)
t965 = t9**(1.2) !t9**(6/5)
t938 = t9**(.375) !t9**(3/8)
t9m13 = 1.0/t913 !t9**(1/3)
t9m23 = 1.0/t923 !t9**(-2/3)
t9m32 = 1.0/t932 !t9**(-3/2)
t9m65 = 1.0/t965 !t9**(-6/5)
t9a = t9 !For reaction 82.
| /(1.+4.78e-2*t9+7.56e-3*t953/(1.+4.78e-2*t9)**(2./3.))
t9a13 = t9a**(.33333333) !t9a**(1/3)
t9a56 = t9a**(.83333333) !t9a**(5/6)
t9b = t9 !For reaction 84.
| /(1.+7.76e-2*t9+2.64e-2*t953/(1.+7.76e-2*t9)**(2./3.))
t9b13 = t9b**(.33333333) !t9b**(1/3)
t9b56 = t9b**(.83333333) !t9b**(5/6)
C20--------NEUTRON, PHOTON REACTIONS--------------------------------------------
C.......C12(n,g)C13................(Wagoner 1969)
f(65) = 4.50e+2
C.......C13(n,g)C14................(Wagoner 1969)
f(66) = 1.19e+2 + 2.38e+5*t9m32*ex(-1.67/t9)
C.......N14(n,g)N15................(Wagoner 1969)
f(67) = 9.94e+3
C30--------NEUTRON, PROTON REACTIONS--------------------------------------------
C.......N13(n,p)C13................(Caughlan-Fowler 1988)
f(68) = 1.88e+8*(1.-.167*t912+.037*t9)
C.......N14(n,p)C14................(Caughlan-Fowler 1988)
f(69) = 2.39e+5*(1.+.361*t912+.502*t9)
| + 1.112e+8/t912*ex(-4.983/t9)
C.......O15(n,p)N15................(Caughlan-Fowler 1988)
f(70) = 3.50e+8*(1.+.452*t912-.191*t9)
C40--------NEUTRON, ALPHA REACTIONS---------------------------------------------
C.......O15(n,a)C12................(Caughlan-Fowler 1988)
f(71) = 3.50e+7*(1.+.188*t912+.015*t9)
C50--------PROTON, PHOTON REACTIONS---------------------------------------------
C.......C12(p,g)N13................(Caughlan-Fowler 1988)
f(72) = 2.04e+7*t9m23*ex(-13.690/t913-(t9/1.500)**2)
| *(1.+.030*t913+1.19*t923+.254*t9+2.06*t943+1.12*t953)
| + 1.08e+5*t9m32*ex(-4.925/t9)
| + 2.15e+5*t9m32*ex(-18.179/t9)
C.......C13(p,g)N14................(Caughlan-Fowler 1988)
f(73) = 8.01e+7*t9m23*ex(-13.717/t913-(t9/2.000)**2)
| *(1.+.030*t913+.958*t923+.204*t9+1.39*t943+.753*t953)
| + 1.21e+6*t9m65*ex(-5.701/t9)
C.......C14(p,g)N15................(Caughlan-Fowler 1988)
f(74) = 6.80e+6*t9m23*ex(-13.741/t913-(t9/5.721)**2)
| *(1.+.030*t913+.503*t923+.107*t9+.213*t943+.115*t953)
| + 5.36e+3*t9m32*ex(-3.811/t9)
| + 9.82e+4*t9m13*ex(-4.739/t9)
C.......N13(p,g)O14................(Caughlan-Fowler 1988)
f(75) = 4.04e+7*t9m23*ex(-15.202/t913-(t9/1.191)**2)
| *(1.+.027*t913-.803*t923-.154*t9+5.00*t943+2.44*t953)
| + 2.43e+5*t9m32*ex(-6.348/t9)
C.......N14(p,g)O15................(Caughlan-Fowler 1988)
f(76) = 4.90e+7*t9m23*ex(-15.228/t913-(t9/3.294)**2)
| *(1.+.027*t913-.778*t923-.149*t9+.261*t943+.127*t953)
| + 2.37e+3*t9m32*ex(-3.011/t9)
| + 2.19e+4*ex(-12.530/t9)
C.......N15(p,g)O16................(Caughlan-Fowler 1988)
f(77) = 9.78e+8*t9m23*ex(-15.251/t913-(t9/.450)**2)
| *(1.+.027*t913+.219*t923+.042*t9+6.83*t943+3.32*t953)
| + 1.11e+4*t9m32*ex(-3.328/t9)
| + 1.49e+4*t9m32*ex(-4.665/t9)
| + 3.80e+6*t9m32*ex(-11.048/t9)
C60--------PROTON, ALPHA REACTIONS----------------------------------------------
C.......N15(p,a)C12................(Caughlan-Fowler 1988)
f(78) = 1.08e+12*t9m23*ex(-15.251/t913-(t9/.522)**2)
| *(1.+.027*t913+2.62*t923+.501*t9+5.36*t943+2.60*t953)
| + 1.19e+8*t9m32*ex(-3.676/t9)
| + 5.41e+8/t912*ex(-8.926/t9)
| + 4.72e+7*t9m32*ex(-7.721/t9)
| + 2.20e+8*t9m32*ex(-11.418/t9)
C70--------ALPHA, PHOTON REACTIONS----------------------------------------------
C.......C12(a,g)O16................(Caughlan-Fowler 1988)
f(79) = 1.04e+8/t9**2*ex(-32.120/t913-(t9/3.496)**2)
| /(1.+.0489*t9m23)**2
| + 1.76e+8/(t9)**2/(1.+.2654*t9m23)**2*ex(-32.120/t913)
| + 1.25e+3*t9m32*ex(-27.499/t9)
| + 1.43e-2*(t9)**5*ex(-15.541/t9)
C80--------ALPHA, PROTON REACTIONS----------------------------------------------
C.......B10(a,p)C13................(Wagoner 1969)
f(80) = 9.60e+14*t9m23*ex(-27.99/t913)
C.......B11(a,p)C14................(Caughlan-Fowler 1988)
f(81) = 5.37e+11*t9m23*ex(-28.234/t913-(t9/0.347)**2)
| *(1.+.015*t913+5.575*t923+.576*t9+15.888*t943+4.174*t953)
| + 5.44e-3*t9m32*ex(-2.827/t9)
| + 3.36e+2*t9m32*ex(-5.178/t9)
| + 5.32e+6/t938*ex(-11.617/t9)
C.......C11(a,p)N14................(Caughlan-Fowler 1988)
f(82) = 7.15e+15*t9a56*t9m32*ex(-31.883/t9a13)
C.......N12(a,p)O15................(Caughlan-Fowler 1988)
f(83) = 5.59e+16*t9m23*ex(-35.60/t913)
C.......N13(a,p)O16................(Caughlan-Fowler 1988)
f(84) = 3.23e+17*t9b56*t9m32*ex(-35.829/t9b13)
C90--------ALPHA, NEUTRON REACTIONS---------------------------------------------
C.......B10(a,n)N13................(Caughlan-Fowler 1988)
f(85) = 1.20e+13*t9m23*ex(-27.989/t913-(t9/9.589)**2)
C.......B11(a,n)N14................(Caughlan-Fowler 1988)
f(86) = 6.97e+12*t9m23*ex(-28.234/t913-(t9/0.140)**2)
| *(1.+.015*t913+8.115*t923+.838*t9+39.804*t943
| +10.456*t953)
| + 1.79e+0*t9m32*ex(-2.827/t9)
| + 1.71e+3*t9m32*ex(-5.178/t9)
| + 4.49e+6*t935*ex(-8.596/t9)
C.......B12(a,n)N15................(Wagoner 1969)
f(87) = 3.04e+15*t9m23*ex(-28.45/t913)
C.......C13(a,n)O16................(Caughlan-Fowler 1988)
f(88) = 6.77e+15*t9m23*ex(-32.329/t913-(t9/1.284)**2)
| *(1.+.013*t913+2.04*t923+.184*t9)
| + 3.82e+5*t9m32*ex(-9.373/t9)
| + 1.41e+6*t9m32*ex(-11.873/t9)
| + 2.00e+9*t9m32*ex(-20.409/t9)
| + 2.92e+9*t9m32*ex(-29.283/t9)
C........He+(H,γ)HeH+.........Added by Ninja
f(89) = 4.16e-16*((t9/300)**(-0.37))*ex(-t9/87600) ! He+(h,γ)HeH+
C........H2(p,γ)H3+.........Added by Ninja
f(90) = 1.0e-16
C........HeH(d,He)H3+.........Added by Ninja
f(91) = 1.53e-9*((t9/300)**(0.24))*ex(-t9/14800)
C........He(H2+,H)HeH+.........Added by Ninja
f(92) = 3.0e-10*ex(-6720*t9m1)
C........He+(p,γ)HeH+.........Added by Ninja
f(93) = 8.0e-20*((t9/300)**(-0.24))*ex(-t9/4000) ! He+(p,γ)HeH+
C........He+(pγ,2γ)HeH+.........Added by Ninja
f(94) = 1.5e-20*ex(-200*t9m1) ! He+(pγ,2γ)HeH+
C........H2(p,e-)H3+.........Added by Ninja
f(95) = 4.7e-9*((t9/300)**(-0.5))
C........He+(d,γ)HeD+.........Added by Ninja
f(96) = 5.0e-16*((t9/300)**(-0.37))*ex(-t9/87600)
/ + 1.0e-19*((t9/300)**(-0.24))*ex(-t9/4000)
/ + 1.5e-21*ex(-200/t9)
C........HeD+(p,d)HeD+.........Added by Ninja
f(97) = 8.0e-10*ex(-468/t9)
C........D(p,γ)HD+.........Added by Ninja
f(98) = 3.9e-19*((t9/300)**(1.8))*ex(-20/t9)
/ + 2*1.5e-9*((t9/300)**(-0.1))
| + 1.05e-26**((t9/300)**(0.09))*ex(-t9/7000)
C........HD+(H2,d)H3+.........Added by Ninja
f(99) = 1.05e-9
C........HD+(e-,p)d.........Added by Ninja
f(100) = 3.4e-9*((t9/300)**(-0.4))
C........HD+(p,H2)d.........Added by Ninja
f(101) = 1.0e-9*ex(-154/t9)
C........D(d,p)HD+.........Added by Ninja
f(102) = 1.07e-9*((t9/300)**(0.062))*ex(-t9/41400)
| + 7.5e-11*ex(-3820/t9)
| + 2.1e-9
C........HeH(d,He)H3+.........Added by Ninja
f(103) = 1.53e-9*((t9/300)**(0.24))*ex(-t9/14800)
C........HeH(D,He)HD+.........Added by Ninja
f(104) = 8.5e-10*((t9/300)**(0.13))*ex(-t9/33100)
C........He(HD+,d)HeH+.........Added by Ninja
f(105) = 3.0e-10*ex(-6720/t9)
C........He(HD+,p)HeD+.........Added by Ninja
f(106) = 3.0e-10*ex(-6720/t9)
C........H3(HD+,d)H2D+.........Added by Ninja
f(107) = 1.4e-9
C........H2D+(p,d)H3+.........Added by Ninja
f(108) = 1.0e-9*ex(-632/t9)
C........H2D+(d,HD)H3+.........Added by Ninja
f(109) = 1.7e-9*ex(-150/t9)
C........H2(d,γ)H2D+.........Added by Ninja
f(110) = 1.0e-20 + 7.0e-18*((t9/300)**(1.8))*ex(-20/t9)
C........HD(p,γ)H2D+.........Added by Ninja
f(111) = 1.0e-20
C........HeD+(p,He)HD+.........Added by Ninja
f(112) = 9.1e-10*((t9/300)**(0.13))*ex(-t9/33100)
C........HeD+(e-,He)D.........Added by Ninja
f(113) = 3.0e-8*((t9/300)**(-0.47))
C........HD+(p,d)H2.........Added by Ninja
f(114) = 1.0e-9*ex(-457/t9)
| + 7.5e-11*ex(-4240/t9)
| + 1.0e-9*ex(-154/t9)
C........HeH+(d,p)HeD+.........Added by Ninja
f(115) = 1.0e-9
C........HD+(d,p)H2D+.........Added by Ninja
f(116) = 2*1.05e-9
C........H3+(d,p)H2D+.........Added by Ninja
f(117) = 1.0e-9
C........H2D+(e-,p)HD+.........Added by Ninja
f(118) = 1.2e-8*((t9/300)**(-0.5))
C........H2D+(e-,d)D.........Added by Ninja
f(119) = 4.2e-9*((t9/300)**(-0.5))
C........H2D+(e-,2p)D.........Added by Ninja
f(120) = 4.38e-8*((t9/300)**(-0.5))
C........H3+(e-,p)D .........Added by Ninja
f(121) = 4.0e-8*((t9/300)**(-0.5))
C........H3+(e-,2p)p.........Added by Ninja
f(122) = 1.6e-7*((t9/300)**(-0.5))
C........H3+(H-,2p)D .........Added by Ninja
f(123) = 2.3e-7*((t9/300)**(-0.5))
RETURN
C----------REFERENCES-----------------------------------------------------------
C Caughlan, G.R., and Fowler, W.A., 1988, Atomic Data and Nuclear Data
C Tables, 40, 283.
C Wagoner, R.V.,1969, Ap. J. Suppl. No. 162, 18, 247.
END
C========================IDENTIFICATION DIVISION================================
BLOCK DATA
C----------PARAMETERS.
PARAMETER (nrec=123) !Number of nuclear reactions. (Ninja)
PARAMETER (nnuc=30) !Number of nuclides in calculation. (Ninja)
C----------COMMON AREAS.
COMMON /recpr0/ reacpr !Reaction parameter values.
COMMON /compr0/ cy0,ct0,t9i0,t9f0,ytmin0,inc0 !Default comp parameters.
COMMON /modpr0/ c0,cosmo0,xi0 !Default model parameters.
COMMON /varpr0/ dt0,eta0 !Default variationl params.
COMMON /nucdat/ am,zm,dm !Nuclide data.
C==========================DECLARATION DIVISION=================================
C----------REACTION PARAMETERS VALUES.
REAL reacpr(nrec,8) !Reaction parameters.
C----------DEFAULT COMPUTATION PARAMETERS.
REAL cy0 !Default time step limiting constant.
REAL ct0 !Default time step limiting constant.
REAL t9i0 !Default initial temperature (in 10**9 K).
REAL t9f0 !Default final temperature (in 10**9 K).
REAL ytmin0 !Default smallest abundances allowed.
INTEGER inc0 !Default accumulation increment.
C----------DEFAULT MODEL PARAMETERS.
REAL c0(3) !c0(1) is default variation of grav constant.
| !c0(2) is default neutron half-life.
| !c0(3) is default number of neutrinos.
REAL cosmo0 !Default cosmological constant.
REAL xi0(3) !Default neutrino degeneracy parameters.
C----------DEFAULT VARIATIONAL PARAMETERS.
REAL dt0 !Default initial time step.
REAL eta0 !Default baryon-to-photon ratio.
C----------NUCLIDE DATA.
REAL am(nnuc) !Atomic number of nuclide.
REAL zm(nnuc) !Charge of nuclide.
REAL dm(nnuc) !Mass excess of nuclide.
C==============================DATA DIVISION====================================
C Nuclide and corresponding number
C --------------------------------
C 1) N 7) Li6 13) B10 19) C13 25) O15
C 2) P 8) Li7 14) B11 20) N13 26) O16
C 3) H2 9) Be7 15) C11 21) C14 27) HeH
C 4) H3 10) Li8 16) B12 22) N14 28) HeD
C 5) He3 11) B8 17) C12 23) O14 29) HD
C 6) He4 12) Be9 18) N12 24) N15 30) H2D
C-----------NUCLIDE DATA.
DATA am /1.,1.,2.,3.,3.,4.,6.,7.,7.,8.,8.,9.,10.,11.,11.,12.,
| 12.,12.,13.,13.,14.,14.,14.,15.,15.,16.,5.,6.,3.,4 / ! Ninja
DATA zm /0.,1.,1.,1.,2.,2.,3.,3.,4.,3.,5.,4.,5.,5.,6.,5.,
| 6.,7.,6.,7.,6.,7.,8.,7.,8.,8.,3.,4.,2.,3 / ! Ninja
DATA dm /.008665,.007825,.014102,.016050,.016030,.002603,.015125,
| .016004,.016929,.022487,.024609,.012186,.012939,.009305,
| .011432,.014354,.000000,.018641,.003354,.005738,.003242,
| .003074,.008597,.000108,.003070,-.005085,.01054,.01,.01,
| .01 / ! Ninja
C----------REACTION RATE COEFFICIENTS (Ref 1).
DATA ((reacpr(i,j),j=1,8),i=1,11) /
C reac# type n1 n2 n3 n4 rev-coeff q-value
C ---- ---- -- -- -- -- --------- -------
| 1.,1., 1.,0.,0., 2., 0.0 , 0.0 , !N->P
| 2.,1., 4.,0.,0., 5., 0.0 , 0.0 , !H3->He3
| 3.,4.,10.,0.,0., 6., 0.0 , 0.0 , !Li8->2He4
| 4.,1.,16.,0.,0.,17., 0.0 , 0.0 , !B12->C12
| 5.,1.,21.,0.,0.,22., 0.0 , 0.0 , !C14->N14
| 6.,4.,11.,0.,0., 6., 0.0 , 0.0 , !B8->2He4
| 7.,1.,15.,0.,0.,14., 0.0 , 0.0 , !C11->B11
| 8.,1.,18.,0.,0.,17., 0.0 , 0.0 , !N12->C12
| 9.,1.,20.,0.,0.,19., 0.0 , 0.0 , !N13->C13
| 10.,1.,23.,0.,0.,22., 0.0 , 0.0 , !O14->N14
| 11.,1.,25.,0.,0.,24., 0.0 , 0.0 / !O15->N15
DATA ((reacpr(i,j),j=1,8),i=12,22) /
C reac# type n1 n2 n3 n4 rev-coeff q-value
C ---- ---- -- -- -- -- --------- -------
| 12.,2., 2.,1.,0., 3., 0.471, 25.82, !H(n,g)H2
| 13.,2., 3.,1.,0., 4., 1.63 , 72.62, !H2(n,g)H3
| 14.,2., 5.,1.,0., 6., 2.61 , 238.81, !He3(n,g)He4
| 15.,2., 7.,1.,0., 8., 1.19 , 84.17, !Li6(n,g)Li7
| 16.,3., 5.,1.,2., 4., 1.002, 8.863, !He3(n,p)H3
| 17.,3., 9.,1.,2., 8., 0.998, 19.081, !Be7(n,p)Li7