This repository has been archived by the owner on Feb 27, 2020. It is now read-only.
-
Notifications
You must be signed in to change notification settings - Fork 0
/
expr.g
105 lines (81 loc) · 1.35 KB
/
expr.g
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
program:
{ decl }
;
decl:
"var" "ID" type ";"
| "func" "ID" "(" [ param-list ] ")" [ type ] block
;
param-list:
"ID" type { "," "ID" type }
;
type:
"[" arithexpr "]" type
| basic-type
;
basic-type:
"char" | "bool" | "int" | "real"
;
block:
"{" { decl } stmts "}"
;
stmts:
{ stmt }
;
stmt:
basic-stmt ";"
| "if" "(" expr ")" stmt [ "else" stmt ] ";"
| "while" "(" expr ")" stmt ";"
| "do" stmt "while" "(" expr ")" ";"
| "break" ";"
| "return" [ expr ] ";"
| block
;
basic-stmt:
assign-expr
;
assign-expr:
expr { "=" expr }
;
expr:
join { "||" join }
;
join:
equality { "&&" equality }
;
equality:
relexp { ( "==" | "!=") relexp }
;
relexp:
arithexpr [ ("<" | ">" | "<=" | ">=") arithexpr ]
;
arithexpr:
term { ("+" | "-" ) term }
;
term:
unary { ("*" | "/") unary }
;
unary:
("!" | "-" | "+") unary
| factor
;
factor:
postfix-expr { "^" postfix-expr }
;
postfix-expr:
primary [ argument-list ]
;
argument-list:
"(" [ expr { "," expr } ] ")"
;
lvalue:
"IDENT" { "[" expr "]" }
;
primary:
"(" expr ")"
| lvalue
| "NUMBER"
| "CHAR-LITERAL"
| "true"
| "false"
| "BLTIN"
;