pcsx2-bin: "init" at 1.7.5779

Basically, extirpate the Darwin-specific code from the previous pcsx2.

pkgs/by-name/pc/pcsx2-bin/package.nix

@@ -0,0 +1,58 @@
+{
+  lib,
+  fetchurl,
+  makeWrapper,
+  stdenvNoCC,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "pcsx2";
+  version = "1.7.5779";
+
+  src = fetchurl {
+    url = "https://github.com/PCSX2/pcsx2/releases/download/v${finalAttrs.version}/pcsx2-v${finalAttrs.version}-macos-Qt.tar.xz";
+    hash = "sha256-QdYV63lrAwYSDhUOy4nB8qL5LfZkrg/EYHtY2smtZuk=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  dontPatch = true;
+  dontConfigure = true;
+  dontBuild = true;
+
+  sourceRoot = ".";
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/{bin,Applications}
+    cp -r "PCSX2-v${finalAttrs.version}.app" $out/Applications/PCSX2.app
+    makeWrapper $out/Applications/PCSX2.app/Contents/MacOS/PCSX2 $out/bin/pcsx2-qt
+    runHook postInstall
+  '';
+
+  meta = {
+    homepage = "https://pcsx2.net";
+    description = "Playstation 2 emulator; precompiled binary for MacOS x64, repacked from official website";
+    longDescription = ''
+      PCSX2 is an open-source PlayStation 2 (AKA PS2) emulator. Its purpose is
+      to emulate the PS2 hardware, using a combination of MIPS CPU Interpreters,
+      Recompilers and a Virtual Machine which manages hardware states and PS2
+      system memory. This allows you to play PS2 games on your PC, with many
+      additional features and benefits.
+    '';
+    license = with lib.licenses; [
+      gpl3Plus
+      lgpl3Plus
+    ];
+    mainProgram = "pcsx2-qt";
+    maintainers = with lib.maintainers; [
+      hrdinka
+      govanify
+      matteopacini
+    ];
+    platforms = lib.systems.inspect.patternLogicalAnd
+      lib.systems.inspect.patterns.isDarwin
+      lib.systems.inspect.patterns.isx86_64;
+    sourceProvenance = lib.sourceTypes.binaryNativeCode;
+  };
+})