How do I configure the backend? Error initializing winit event loop

[WhiteBlackGoose]

Hi.

I cloned the template, replaced placeholders and ran cargo run

Error: Other("Could not initialize backend.\nError from Winit backend: Error initializing winit event loop: os error at /home/goose/.cargo/registry/src/index.crates.io-6f17d22bba15001f/winit-0.29.4/src/platform_impl/linux/wayland/event_loop/mod.rs:81: The wayland library could not be loaded\nNo backends configured.")

I'm on NixOS + Wayland (hyprland).

How to configure the backend? (tried SLINT_BACKEND=winit but same result)

[tronical]

Slint will dynamically open the wayland libraries, it will try to open libwayland-client.so.0 or libwayland-client.so. Are those accessible in your Nix environment?

[WhiteBlackGoose]

Thank you so much. For fellow nix people,

LD_LIBRARY_PATH = "$LD_LIBRARY_PATH:${ with pkgs; lib.makeLibraryPath [
    wayland
    libxkbcommon
    fontconfig
] }";

[jasper-at-windswept]

@WhiteBlackGoose
Where in my nix configuration does this go?

[WhiteBlackGoose]

@jasper-at-windswept as an attribute of your shell. E. g. devShells.default.LD_LIBRARY_PATH = .... If you want globally, look into system environmental variables for nixos.

[jasper-at-windswept]

Thanks!

[gordug]

Are there any plans for these to be bundles with rust builds, similar to how you can have self-contained apps in.Net?

[txtyash]

For fellow nix newbies like me, this is where it goes in my flake.nix:

          devShells.default = mkShell {
            buildInputs = [
              openssl
              pkg-config
              rust-bin.beta.latest.default
            ];
            packages = [ pkgs.bashInteractive ];
            # TODO: Read on shellHooks
            shellHook = ''
              # alias ls=eza
              # alias find=fd
            '';
            LD_LIBRARY_PATH = "$LD_LIBRARY_PATH:${ with pkgs; lib.makeLibraryPath [
                wayland
                libxkbcommon
                fontconfig
            ] }";
          };

[sakshatshinde]

If someone wants to use it with oxalica/rust-overlay

# flake.nix
{
  description = "rust devshell for linpull";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, rust-overlay, flake-utils, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        overlays = [ (import rust-overlay) ];
        pkgs = import nixpkgs {
          inherit system overlays;
        };
      in
      {
        devShells.default = with pkgs; mkShell {
          buildInputs = [
            openssl
            pkg-config
            eza
            fd
            rust-bin.beta.latest.default
          ];
          
          LD_LIBRARY_PATH = "$LD_LIBRARY_PATH:${ with pkgs; lib.makeLibraryPath [
		                wayland
		                libxkbcommon
		                fontconfig
		            ] }";

          shellHook = ''
            alias ls=eza
            alias find=fd
          '';
        };
      }
   );
}

Run nix develop in the project root